Vulture Aid in Scripts

Hello guys
my name is xSanchez78
and today i have something
that has been released before
in the community, but my
version is improved
and completely remastered
Today I have for you:

Vulture Aid

I have spent about 2 months scripting
this, making sure that the perk is exactly
like black ops 2 buried, and has no
glitched or bugs. And it is PERFECT!

Perk Features:
   When you buy this perk, you get three
   forms of aids. The first form is in
   powerups. Each zombie has a 40% chance
   of dropping a vulture aid powerup.
   They will either be an ammo pack or
   a points pack. Ammo packs will add
   5 - 10 bullets back into your current
   weapons stock, and point packs will
   give you 20 - 30 points. Only the player
   who kills the zombie can see and pick
   up the powerup if that player has vulture
   aid. The second aid is a green smell.
   One zombie per wave spawns with a green
   smell, and when you kill it, it drops
   the smell for players with vulture aid
   to be able to come and hide in. Zombies
   will ignore players that are in the smell.
   Only players with vulture aid can see and
   use the smell. Finally, you get one more
   aid: waypoints. Waypoints show up around
   the map, showing you where things are
   like perks, wall weapons, and pap. It also
   shows the location of the current box.

Let's Get Started!

Xmodels:

This tutorial does not provide xmodels for you.
It is up to you to export the xmodels, as posting
them in download links is against the UGX Mods
rules. But here is an Easy-To-Follow tutorial:

http://www.zombiemodding.com/index.php?topic=12436.0

Follow that and you will learn how to port xmodels.
The models you need are "bo2_p6_zm_vending_vultureaid",
"bo2_p6_zm_vending_vultureaid_on", "bo2_t6_wpn_zmb_perk_bottle_vulture_view",
"bo2_t6_wpn_zmb_perk_bottle_vulture_world", "bo2_p6_zm_perk_vulture_points",
and "bo2_p6_zm_perk_vulture_ammo". The models
in lime may not have the prefix "bo2_" but just look for these
names and when you convert them, make sure they match
or else this tutorial will not work properly.
In mod.csv, be sure to add the following:

Code Snippet

Plaintext

xmodel,bo2_p6_zm_vending_vultureaid
xmodel,bo2_p6_zm_vending_vultureaid_on
xmodel,bo2_t6_wpn_zmb_perk_bottle_vulture_view
xmodel,bo2_t6_wpn_zmb_perk_bottle_vulture_world
xmodel,bo2_p6_zm_perk_vulture_points
xmodel,bo2_p6_zm_perk_vulture_ammo

Fx:

Download the fx file at the bottom of this
tut. They are bamskater's Vulture Aid Fx that he
has given me permission to use. If you don't believe
that, ask him youself. Put the fx into "root/raw/fx".
In mod.csv, be sure to add the following:

Code Snippet

Plaintext

fx,vulture_smell
fx,vulture_treasure

Weapons:

You are probably thinking, what do weapons
have to do with this? Well the weapon
I am talking about is the perk bottle that
you drink when you buy the perk. If you
exported all the models correctly in the first
step, you will have the models needed.
First, go to "root/raw/weapons/sp" and find
"zombie_perk_bottle_jugg". Copy it and rename it
to "zombie_perk_bottle_vulture". Now open it
with notepad, and find "GunModel". In the next
set of slashes, it should say "zombie_perk_bottle_jugg".
Rename this to "bo2_t6_wpn_zmb_perk_bottle_vulture_view".
Then find "WorldModel". Next to it, it should say
"zombie_3rd_perk_bottle_jugg". Rename this to
"bo2_t6_wpn_zmb_perk_bottle_vulture_world".
Save & Close. Now you have your weapon file.
Place it in "root/mods/mapname/weapons/sp".
In mod.csv, make sure to add this:

Code Snippet

Plaintext

weapon,sp/zombie_perk_bottle_vulture

Radiant:

In radiant, you need to make your own prefab.
First add a trigger_multiple. Add these KVP's
   targetname - audio_bump_trigger
   script_sound - perks_rattle

This will be the trigger where you go prone
and it gives you 25 points. Now add a script_struct.
Give it these KVP's
   targetname - perksacola
   script_sound - mx_vulture_jingle

This will be the spot where it plays the
perk jingle when it is idle. Now add a
trigger_use. Give it these KVP's:
   targetname - vending_trigger_vulture

This will be the trigger that the players
use to buy the perk. Now add a script_model
Give it these KVP's
   targetname - vending_vulture
   model - bo2_p6_zm_vending_vultureaid

This will be the actual perk model.
Now just add a clip around your perk
and you should have your perk prefab!
Now here is one more thing you need to do.
Add a script_origin where you want the
zombies to retreat to when every player
is in the stink. Give it this KVP
   targetname - vulture_retreat

Images:

All of the shaders you need are at the bottom
attached to this tutorial, just download them.
They are in a .dds format. You need to convert
them and make sure they are the same name as
they are now, otherwise they will not work.

Sounds:

The sounds are also up to you to get.
The functions for playing sound are already
in the script, you just need to do this:
For the stinger sound, in the alias, make
sure you call it "mx_vulture_sting", and for
the jingle call it "mx_vulture_jingle".

Scripts:

Alright, you have done every other step, time for the
last. Scripting. This is the hardest part, there is much to
do. First, copy this script and name it to

"_zombiemode_perks_vulture.gsc"

Code Snippet

Plaintext

#include maps\_utility; 
#include common_scripts\utility;
#include maps\_zombiemode_utility;
#include maps\_hud_util;

init()
{
	UseVultureAidWaypoints( true );
	vending_triggers = GetEntArray( "vending_trigger_vulture", "targetname" );
	if( vending_triggers.size < 1 )
	{
		return;
	}
	PrecacheItem( "zombie_perk_bottle_vulture" );
	PrecacheShader( "vulture_vending_zombies_0" );
	PrecacheShader( "vulture_vending_zombies_1" );
	PrecacheShader( "vulture_vending_zombies_weap" );
	PrecacheShader( "vulture_vending_zombies_box" );
	PrecacheShader( "vulture_pap" );
	PrecacheModel( "bo2_p6_zm_vending_vultureaid_on" );
	PrecacheModel( "bo2_p6_zm_perk_vulture_points" );
	PrecacheModel( "bo2_p6_zm_perk_vulture_ammo" );
	level._effect["vulture_light"] = loadfx("misc/fx_zombie_cola_jugg_on");
	level._effect["vulture_smell"] = Loadfx("vulture_smell");
	level._effect["vulture_powerup"] = Loadfx("vulture_treasure");
	array_thread( vending_triggers, ::vending_trigger_think );
	array_thread( vending_triggers, maps\_zombiemode_perks::electric_perks_dialog );
	level thread turn_vulture_on();
	level thread machine_watcher();
	level.vulture_jingle = 0;
	thread handle_zombies();
	thread handle_players();
}

turn_vulture_on()
{
	machine = getentarray("vending_vulture", "targetname");
	level waittill("juggernog_on");
	for( i = 0; i < machine.size; i++ )
	{
		machine[i] setmodel("bo2_p6_zm_vending_vultureaid_on");
		machine[i] vibrate((0,-100,0), 0.3, 0.4, 3);
		machine[i] playsound("perks_power_on");
		machine[i] thread maps\_zombiemode_perks::perk_fx( "vulture_light" );
 
	}
	level notify( "specialty_ordinance_power_on" );
}

vending_trigger_think()
{
	self SetHintString( &"ZOMBIE_FLAMES_UNAVAILABLE" );
	self SetCursorHint( "HINT_NOICON" );
	self UseTriggerRequireLookAt();
	level waittill( "specialty_ordinance_power_on" );
	perk_hum = spawn("script_origin", self.origin);
	perk_hum playloopsound("perks_machine_loop");
	self thread maps\_zombiemode_perks::check_player_has_perk( "specialty_ordinance" );
	self setHintString( "Press & hold &&1 to buy Vulture Aid [Cost: 3000]" );
	for( ;; )
	{
		self waittill( "trigger", player );
		index = maps\_zombiemode_weapons::get_player_index(player);
		cost = 3000;
		if (player maps\_laststand::player_is_in_laststand() )
		{
			continue;
		}
		if(player in_revive_trigger())
		{
			continue;
		}
		if( player isThrowingGrenade() )
		{
			wait( 0.1 );
			continue;
		}
		if( player isSwitchingWeapons() )
		{
			wait(0.1);
			continue;
		}
		if ( player HasPerk( "specialty_ordinance" ) )
		{
			self playsound("deny");
			player thread maps\_zombiemode_perks::play_no_money_perk_dialog();
			continue;
		}
		if ( player.score < cost )
		{
			self playsound("deny");
			player thread maps\_zombiemode_perks::play_no_money_perk_dialog();
			continue;
		}
		sound = "bottle_dispense3d";
		player achievement_notify( "perk_used" );
		playsoundatposition(sound, self.origin);
		player maps\_zombiemode_score::minus_to_player_score( cost ); 
		self thread play_vendor_stings();
		gun = player perk_give_bottle_begin();
		player.is_drinking = 1;
		player waittill_any( "fake_death", "death", "player_downed", "weapon_change_complete" );
		player perk_give_bottle_end( gun );
		player.is_drinking = undefined;
		if ( player maps\_laststand::player_is_in_laststand() )
		{
			continue;
		}
		player SetPerk( "specialty_ordinance" );
		player thread perk_vo();
		player setblur( 4, 0.1 );
		wait(0.1);
		player setblur(0, 0.1);
		player perk_hud_create();
		player.stats["perks"]++;
		bbPrint( "zombie_uses: playername %s playerscore %d round %d cost %d name %s x %f y %f z %f type perk", player.playername, player.score, level.round_number, cost, "specialty_ordinance", self.origin );
		player thread maps\_zombiemode_perks::perk_think( "specialty_ordinance" );

	}
}

perk_hud_create()
{
	if ( !IsDefined( self.perk_hud ) )
	{
		self.perk_hud = [];
	}
	hud = create_simple_hud( self );
	hud.foreground = true; 
	hud.sort = 1; 
	hud.hidewheninmenu = false; 
	hud.alignX = "left"; 
	hud.alignY = "bottom";
	hud.horzAlign = "left"; 
	hud.vertAlign = "bottom";
	hud.x = self.perk_hud.size * 30; 
	hud.y = hud.y - 70; 
	hud.alpha = 1;
	hud SetShader( "vulture_vending_zombies_0", 24, 24 );
	self.perk_hud[ "specialty_ordinance" ] = hud;
}

perk_give_bottle_begin()
{
	self DisableOffhandWeapons();
	self DisableWeaponCycling();
	self AllowLean( false );
	self AllowAds( false );
	self AllowSprint( false );
	self AllowProne( false );		
	self AllowMelee( false );
	wait( 0.05 );
	if ( self GetStance() == "prone" )
	{
		self SetStance( "crouch" );
	}
	gun = self GetCurrentWeapon();
	self GiveWeapon( "zombie_perk_bottle_vulture" );
	self SwitchToWeapon( "zombie_perk_bottle_vulture" );
	return gun;
}

perk_give_bottle_end( gun )
{
	assert( gun != "zombie_perk_bottle_doubletap" );
	assert( gun != "zombie_perk_bottle_revive" );
	assert( gun != "zombie_perk_bottle_jugg" );
	assert( gun != "zombie_perk_bottle_sleight" );
	assert( gun != "zombie_perk_bottle_vulture" );
	assert( gun != "syrette" );
	self EnableOffhandWeapons();
	self EnableWeaponCycling();
	self AllowLean( true );
	self AllowAds( true );
	self AllowSprint( true );
	self AllowProne( true );		
	self AllowMelee( true );
	if ( self maps\_laststand::player_is_in_laststand() )
	{
		self TakeWeapon("zombie_perk_bottle_vulture");
		return;
	}
	if ( gun != "none" && gun != "mine_bouncing_betty" )
	{
		self SwitchToWeapon( gun );
	}
	else 
	{
		primaryWeapons = self GetWeaponsListPrimaries();
		if( IsDefined( primaryWeapons ) && primaryWeapons.size > 0 )
		{
			self SwitchToWeapon( primaryWeapons[0] );
		}
	}
	self TakeWeapon("zombie_perk_bottle_vulture");
}

perk_vo()
{
	self endon("death");
	self endon("disconnect");
	index = maps\_zombiemode_weapons::get_player_index(self);
	if(!isdefined (level.player_is_speaking))
	{
		level.player_is_speaking = 0;
	}
	player_index = "plr_" + index + "_";
	wait(1.0);
	self maps\_zombiemode_spawner::do_player_playdialog(player_index, "vox_perk_jugga_0", 0.25);
}

machine_watcher()
{
	level thread machine_watcher_factory();
}

machine_watcher_factory()
{
	level waittill("specialty_ordinance_power_on");
	temp_machines = getstructarray("perksacola", "targetname");
	for (x = 0; x < temp_machines.size; x++)
	{
		if (temp_machines[x].script_sound == "mx_vulture_jingle")
		{
			temp_machines[x] thread perks_a_cola_jingle();
		}
	}

}

play_vendor_stings()
{	
	if(!IsDefined (level.vulture_jingle))
	{
		level.vulture_jingle = 0;
	}
	if(!IsDefined (level.eggs))
	{
		level.eggs = 0;
	}
	if (level.eggs == 0)
	{
		if(level.vulture_jingle == 0 ) 
		{
			level.vulture_jingle = 1;		
			temp_org_vulture_s = spawn("script_origin", self.origin);		
			temp_org_vulture_s playsound ("mx_vulture_sting", "sound_done");
			temp_org_vulture_s waittill("sound_done");
			level.vulture_jingle = 0;
			temp_org_vulture_s delete();
		}
	}
}

perks_a_cola_jingle()
{	
	self thread maps\_zombiemode_perks::play_random_broken_sounds();
	if(!IsDefined(self.perk_jingle_playing))
	{
		self.perk_jingle_playing = 0;
	}
	if (!IsDefined (level.eggs))
	{
		level.eggs = 0;
	}
	while(1)
	{
		wait(randomfloatrange(31,45));
		if(randomint(100) < 15 && level.eggs == 0)
		{
			level notify ("jingle_playing");
			playsoundatposition ("electrical_surge", self.origin);
			if(level.vulture_jingle == 0) 
			{
				level.vulture_jingle = 1;
				temp_org_vulture = spawn("script_origin", self.origin);
				wait(0.05);
				temp_org_vulture playsound (self.script_sound, "sound_done");
				temp_org_vulture waittill("sound_done");
				level.vulture_jingle = 0;
				temp_org_vulture delete();
			}
			self thread maps\_zombiemode_perks::play_random_broken_sounds();
		}		
	}	
}

handle_players()
{
	flag_wait( "all_players_connected" );
	players = get_players();
	for( i = 0; i < players.size; i++ )
	{
		players[i] thread vulture_aid_stink();
		players[i] thread vulture_aid_hud();
	}
}

handle_zombies()
{
	thread handle_stink_retreat();
	while(1)
	{
		zombies = getaispeciesarray( "axis", "all" );
		for( i = 0; i < zombies.size; i++ )
		{
			if( !isDefined( zombies[i].vulture_aid ) )
			{
				zombies[i].vulture_aid = true;
				zombies[i] thread init_smell();
				zombies[i] thread init_powerups();
			}
		}
		wait 0.5;
	}
}

handle_stink_retreat()
{
	point = getEnt( "vulture_retreat", "targetname" );
	point create_zombie_point_of_interest( 15360, 960, 100000, true );
	point.attract_to_origin = false;
	while(1)
	{
		if( zombies_should_retreat() )
		{
			point.attract_to_origin = true;
			while( zombies_should_retreat() )
			{
				wait 0.01;
			}
			point.attract_to_origin = false;
		}
		wait 0.1;
	}
}

zombies_should_retreat()
{
	players = get_players();
if( ( players.size == 1 && players[0].isStinky && players[0] hasPerk( "specialty_ordinance" ) ) 
|| ( players.size == 2 && players[0].isStinky && players[0] hasPerk( "specialty_ordinance" ) && players[1].isStinky && players[1] hasPerk( "specialty_ordinance" ) ) 
|| ( players.size == 3 && players[0].isStinky && players[0] hasPerk( "specialty_ordinance" ) && players[1].isStinky && players[1] hasPerk( "specialty_ordinance" ) && players[2].isStinky && players[2] hasPerk( "specialty_ordinance" ) ) 
|| ( players.size == 4 && players[0].isStinky && players[0] hasPerk( "specialty_ordinance" ) && players[1].isStinky && players[1] hasPerk( "specialty_ordinance" ) && players[2].isStinky && players[2] hasPerk( "specialty_ordinance" ) && players[3].isStinky && players[3] hasPerk( "specialty_ordinance" ) ) )
	{
		return true;
	}
	return false;
}

init_smell()
{
	if( num_zombies_smelly() < 1 )
	{
		self.isSmelly = true;
		self.vulture_fx = spawn( "script_model", self.origin );
		self.vulture_fx.angles = self.angles;
		self.vulture_fx setmodel( "tag_origin" );
		self.vulture_fx linkTo( self );
		self.vulture_fx thread play_vulture_fx();
		self waittill( "death" );
		stinky_area = spawn( "script_model", self.origin );
		stinky_area.angles = self.angles;
		stinky_area setmodel( "tag_origin" );
		stinky_area thread play_vulture_fx();
		self.vulture_fx notify( "stop_fx_check" );
		self.vulture_fx delete();
		stinky_area.targetname = "vulture_stinky_point";
		wait 20;
		stinky_area notify( "stop_fx_check" );
		stinky_area delete();
	}
}

num_zombies_smelly()
{
	zombies = getaispeciesarray( "axis", "all" );
	count = 0;
	for( i = 0; i < zombies.size; i++ )
	{
		if( isDefined( zombies[i].isSmelly ) )
		{
			count++;
		}
	}
	return count;
}

play_vulture_fx()
{
	self endon( "stop_fx_check" );
	playfxontag( level._effect[ "vulture_smell" ], self, "tag_origin" );
	while(1)
	{
		players = get_players();
		for( i = 0; i < players.size; i++ )
		{
			if( players[i] hasPerk( "specialty_ordinance" ) )
			{
				self SetInvisibleToPlayer( players[i], false );
			}
			else
			{
				self SetInvisibleToPlayer( players[i], true );
			}
		}
		wait 0.1;
	}
}

init_powerups()
{
	self waittill( "death" );
	if( isDefined( self.attacker ) && IsPlayer( self.attacker ) && self.attacker hasPerk( "specialty_ordinance" ) && randomint( 100 ) < 40 )
	{
		treasure = spawn( "script_model", self.origin + ( 0, 0, 16 ) );
		playable_area = getentarray( "playable_area", "targetname" );
		valid_drop = false;
		for( i = 0; i < playable_area.size; i++ )
		{
			if( treasure istouching( playable_area[i] ) )
			{
				valid_drop = true;
			}
		}
		if( !valid_drop )
		{
			treasure delete();
			return;
		}
		if( randomint( 2 ) == 1 )
		{
			treasure setmodel( "bo2_p6_zm_perk_vulture_points" );
			treasure.type = "points";
		}
		else
		{
			treasure setmodel( "bo2_p6_zm_perk_vulture_ammo" );
			treasure.type = "ammo";
		}
		playfxontag( level._effect[ "vulture_powerup" ], treasure, "tag_origin" );
		players = get_players();
		for( i = 0; i < players.size; i++ )
		{
			if( players[i] != self.attacker )
			{
				treasure SetInvisibleToPlayer( players[i], true );
			}
		}
		treasure thread powerup_timeout();
		treasure thread powerup_grab( self.attacker );
	}
}

powerup_timeout()
{
	self endon( "powerup_grabbed" );
	wait 7.5;
	for( i = 0; i < 40; i++ )
	{
		if( i % 2 )
		{
			self hide();
		}
		else
		{
			self show();
		}
		if( i < 15 )
		{
			wait 0.25;
		}
		else if( i < 25 )
		{
			wait 0.125;
		}
		else
		{
			wait 0.05;
		}
	}
	self notify( "powerup_timedout" );
	self delete();
}

powerup_grab( player )
{
	self endon( "powerup_timedout" );
	self endon( "powerup_grabbed" );
	while( isdefined( self ) )
	{
		players = get_players();
		for( i = 0; i < players.size; i++ )
		{
			if( distance( players[i].origin, self.origin ) < 40 && players[i] hasPerk( "specialty_ordinance" ) && players[i] == player )
			{
				fx_model = spawn( "script_model", self.origin );
				fx_model.angles = self.angles;
				fx_model setModel( "tag_origin" );
				playfxontag( level._effect[ "powerup_grabbed" ], fx_model, "tag_origin" );
				playfxontag( level._effect[ "powerup_grabbed_wave" ], fx_model, "tag_origin" );
				players1 = get_players();
				for( j = 0; j < players1.size; j++ )
				{
					if( players1[j] != players[i] )
					{
						fx_model SetInvisibleToPlayer( players1[j], true );
					}
				}
				fx_model thread delete_over_time();
				switch( self.type )
				{
					case "points":
						players[i] maps\_zombiemode_score::add_to_player_score( randomint( 20 ) + 10 );
						playsoundatposition( "vulture_powerup_point_grab", self.origin );
						break;

					case "ammo":
						weapon = players[i] GetCurrentWeapon();
						current = players[i] GetWeaponAmmoStock( weapon );
						players[i] SetWeaponAmmoStock( weapon, current + randomint( 5 ) + 5 );
						playsoundatposition( "vulture_powerup_ammo_grab", self.origin );
						break;

					default:
						break;
				}
				wait( 0.1 );
				playsoundatposition( "vulture_powerup_grab", self.origin );
				self delete();
				self notify( "powerup_grabbed" );
			}
		}
		wait 0.1;
	}
}

delete_over_time()
{
	wait 3;
	self delete();
}

vulture_aid_stink()
{
	while(1)
	{
		if( self player_is_in_stink() && self hasPerk( "specialty_ordinance" ) )
		{
			self.isStinky = true;
			self.ignoreme = true;
			self.perk_hud[ "specialty_ordinance" ] SetShader( "vulture_vending_zombies_1", 24, 24 );
			while( self player_is_in_stink() && self hasPerk( "specialty_ordinance" ) )
			{
				wait 0.1;
			}
			wait 0.1;
			self.isStinky = false;
			self.perk_hud[ "specialty_ordinance" ] SetShader( "vulture_vending_zombies_0", 24, 24 );
			if( !self maps\_laststand::player_is_in_laststand() )
			{
				self.ignoreme = false;
			}
		}
		wait 0.1;
	}
}

player_is_in_stink()
{
	stinky_points = getEntArray( "vulture_stinky_point", "targetname" );
	for( k = 0; k < stinky_points.size; k++ )
	{
		if( distance( self.origin, stinky_points[k].origin ) < 64 )
		{
			return true;
		}		
	}		
	return false;					
}

UseVultureAidWaypoints( use )
{
	level.uses_vulture_hud = use;
}

vulture_aid_hud()
{
	if( !level.uses_vulture_hud )
	{
		return;
	}
	perks = getEntArray( "zombie_vending", "targetname" );
	vultures = GetEntArray( "vending_trigger_vulture", "targetname" );
	weapons = getEntArray( "weapon_upgrade", "targetname" );
	boxes = getEntArray( "treasure_chest_use", "targetname" );
	paps = getEntArray( "zombie_vending_upgrade", "targetname" );
	bowies = getEntArray( "bowie_upgrade", "targetname" );
	betties = getEntArray( "betty_purchase", "targetname" );
	for( k = 0; k < perks.size; k++ )
	{
		self thread vulture_aid_waypoint( perks[k].origin, getVendingShader( perks[k].script_noteworthy ), 1000, false, undefined );
	}
	for( k = 0; k < vultures.size; k++ )
	{
		self thread vulture_aid_waypoint( vultures[k].origin, "vulture_vending_zombies_0", 1000, false, undefined );
	}
	for( k = 0; k < weapons.size; k++ )
	{
		self thread vulture_aid_waypoint( weapons[k].origin, "vulture_vending_zombies_weap", 1000, false, undefined );
	}
	for( k = 0; k < boxes.size; k++ )
	{
		self thread vulture_aid_waypoint( get_real_origin( boxes[k] ), "vulture_vending_zombies_box", 2000, true, boxes[k] );
	}
	for( k = 0; k < paps.size; k++ )
	{
		self thread vulture_aid_waypoint( paps[k].origin, "vulture_pap", 1000, false, undefined );
	}
	for( k = 0; k < bowies.size; k++ )
	{
		self thread vulture_aid_waypoint( bowies[k].origin, "vulture_vending_zombies_weap", 1000, false, undefined );
	}
	for( k = 0; k < betties.size; k++ )
	{
		self thread vulture_aid_waypoint( betties[k].origin, "vulture_vending_zombies_weap", 1000, false, undefined );
	}
}

vulture_aid_waypoint( waypoint_origin, shader, maxdist, isBox, box_trig )
{
	hud = undefined;
	hide_hud = false;
	while(1)
	{
		trig_is_enabled = true;
		if( isBox && isDefined( box_trig ) )
		{
			if( level.chests[ level.chest_index ] != box_trig )
			{
				trig_is_enabled = false;
			}
		}
		canShow = within_fov( self GetEye(), self GetPlayerAngles(), waypoint_origin, cos( 30 ) );
		if( self hasPerk( "specialty_ordinance" ) && distance( self.origin, waypoint_origin ) < maxdist && canShow && trig_is_enabled )
		{
			if( !isDefined( hud ) )
			{
				hud = NewClientHudElem( self );
				hud setShader( shader, 14, 14 );
				hud setWaypoint( false, shader );
				hud.x = waypoint_origin[0];
				hud.y = waypoint_origin[1];
				hud.z = waypoint_origin[2];
				if( distance( self.origin, waypoint_origin ) > 100 )
				{
					hud.alpha = .5;
					hide_hud = false;
				}
				else if( distance( self.origin, waypoint_origin ) < 100 )
				{
					hud.alpha = 0;
					hide_hud = true;
				}
			}
			if( !hide_hud && distance( self.origin, waypoint_origin ) < 100 )
			{
				hud FadeOverTime( .5 );
				hud.alpha = 0;
				hide_hud = true;
			}
			if( hide_hud && distance( self.origin, waypoint_origin ) > 100 )
			{
				hud FadeOverTime( .5 );
				hud.alpha = .5;
				hide_hud = false;
			}
		}
		else
		{
			if( isDefined( hud ) )
			{
				hud destroy();
				hud = undefined;
			}
		}
		wait .1;
	}
}

getVendingShader( note )
{
	switch( note )
	{
		case "specialty_armorvest":
			shader = "specialty_juggernaut_zombies";
			break;

		case "specialty_quickrevive":
			shader = "specialty_quickrevive_zombies";
			break;

		case "specialty_fastreload":
			shader = "specialty_fastreload_zombies";
			break;

		case "specialty_rof":
			shader = "specialty_doubletap_zombies";
			break;

		default:
			shader = "";
			break;
	}
	return shader;		
}

get_real_origin( box )
{
	origin = box.origin;
	if( isDefined( box.disabled ) && box.disabled )
	{
		origin = box.origin + ( 0, 0, 10000 );
	}
	return origin;
}

Now for editing other scripts.
Go into "_zombiemode.gsc".
In "main()", call "maps\_zombiemode_perks_vulture::init();"
under this

Code Snippet

Plaintext

	maps\_zombiemode_blockers_new::init();
	maps\_zombiemode_spawner::init();
	maps\_zombiemode_powerups::init();
	maps\_zombiemode_radio::init();	
	maps\_zombiemode_perks::init();
	maps\_zombiemode_tesla::init();
	maps\_zombiemode_bowie::bowie_init();
	maps\_zombiemode_cymbal_monkey::init();
	maps\_zombiemode_betty::init();
	maps\_zombiemode_timer::init();
	maps\_zombiemode_auto_turret::init();
	maps\_zombiemode_perks_limit::init();
	maps\_zombiemode_auto_turret::init();

in "init()", find this line.

Code Snippet

Plaintext

UseVultureAidWaypoints( true );

Some people do not like using the waypoints
that show up to show you where things are
in the map because it hits the hud limit.
If you want the hud, set it to true, if not, set
it to false. That way you won't hit the hud limit
and it's mapper's choice for those who don't care.

Now you are done scripting!

Your Done!

Make sure you follow each step carefully.
Always remember to watch for updates.
The title will show if i have made an update
on the specific date and everything. If you need help
just comment or PM. Make sure you call
everything in your mod builder and add everything
as i said into mod.csv. This has been tested, but you
may get errors because i quickly scripted the perk
machine logic so that you wouldnt have to add it to
your _zombiemode_perks.gsc like i did. I may have made some
small syntax errors there so just let me know.
Thanks everyone, please credit me, and peace!

Here are some images:

Spoiler: click to open...

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
Box Mappers Elite

UGX-Mods Login

Vulture Aid

Attachments: