Check if the player is reloading in Scripting

Created on: June 26, 2014, 08:38:35 pm

Ege115
Scripter
517 Posts
161 Respect +1

Hi there.

How can I check if the player is currently reloading in an "if" statement?
I know I can use the,

Code Snippet

Plaintext

self waittill("reload_start");

But that wouldn't work very well in my case, I would need an if statement to check if the player is reloading.

How can I check if the player is reloading in that case then?
Thanks in advance.

Last Edit: June 26, 2014, 08:39:40 pm by Ege115

This topic contains a post which is marked as the Best Answer. Click here to view it.

Reply #1 on: June 26, 2014, 08:44:33 pm

daedra descent
Community Daedra
2,789 Posts
230 Respect +1

Code Snippet

Plaintext

self.is_reloading = true;

Maybe?

edit: thats after the waittill() obviously.

Last Edit: June 26, 2014, 08:45:05 pm by daedra descent

Reply #2 on: June 26, 2014, 08:45:38 pm

MakeCents
Scripter
1,895 Posts
791 Respect +1

Quote from: Ege115 on June 26, 2014, 08:38:35 pm

Hi there.

How can I check if the player is currently reloading in an "if" statement?
I know I can use the,
Code Snippet
Plaintext
self waittill("reload_start");
But that wouldn't work very well in my case, I would need an if statement to check if the player is reloading.

How can I check if the player is reloading in that case then?
Thanks in advance.

You could thread a watch for the reload like electric cherry that sets a variable true between "reload_start" and "reload"?

Reply #3 on: June 26, 2014, 09:30:24 pm

Ege115
Scripter
517 Posts
161 Respect +1

Quote from: MakeCents on June 26, 2014, 08:45:38 pm

You could thread a watch for the reload like electric cherry that sets a variable true between "reload_start" and "reload"?

"reload_start" and "reload"? Does waittill("reload") exist?

Or am I just being stupid now?

Edit: I don't know but would this work?

Code Snippet

Plaintext

reload_check()
{
	self endon( "disconnect" );
	self waittill("spawned_player");
 
	self.is_reloading = false;
 
	while(1)
	{
		weapon = self getcurrentweapon();
		clip = self GetWeaponAmmoClip(weapon);
 
		if(clip.size <=0)
		{
		self.is_reloading = true;
		}
	wait .05;
	}
}

Last Edit: June 26, 2014, 09:44:41 pm by Ege115

Reply #4 on: June 26, 2014, 10:02:18 pm

MakeCents
Scripter
1,895 Posts
791 Respect +1

Quote from: Ege115 on June 26, 2014, 09:30:24 pm

"reload_start" and "reload"? Does waittill("reload") exist?

Or am I just being stupid now?

Edit: I don't know but would this work?
Code Snippet
Plaintext
reload_check()
{
	self endon( "disconnect" );
	self waittill("spawned_player");
 
	self.is_reloading = false;
 
	while(1)
	{
		weapon = self getcurrentweapon();
		clip = self GetWeaponAmmoClip(weapon);
 
		if(clip.size <=0)
		{
		self.is_reloading = true;
		}
	wait .05;
	}
}

I'll check it out tonight if you don't have it solved yet. If you don't have electric cherry, Google it. I think there is a script in it that will solve your problem.

Last Edit: June 26, 2014, 10:03:01 pm by MakeCents

Reply #5 on: June 26, 2014, 10:05:08 pm

DuaLVII
Scripter Elite
325 Posts
93 Respect +1

No, Unless, because the player may not reload the weapon through sprinting and change weapons with the variable still set to true, alternatively the player doesn't have enough ammo to reload with which would still keep the variable to true so you'd have to put in several other if's and buts and candy and nuts into it.

I've never check or tried reload checking but if self.is_reloading is an actual variable used to define if the play is reloading or not then you'd wan't to put a check into a flow control that runs all the time to each individual player with a tiiiny little wait within to stop it from going *freezing for 5 seconds so I can return my favourite infinite loop error*
and then passing a notify (( `self notify("reloading")` )) when self.is_reloading is set to true. Of coarse there will be a spam of those notifies unless you also add in another variable into the reload checker function with another if statement to control it. With self notify, in other functions you can just use self waittill from there (( `self waittill("reloading")` ))

But like I said, Never tried it, not even sure if that variable self.is_reloading even exists and if not this reply was a gorgeous waste of time.

Since I lost all my work recently and haven't completely re-installed World at War yet, I can't test it out otherwise I would of before posting this.

Oh Well

Reply #6 on: June 26, 2014, 10:44:23 pm

treminaor
UGX Administrator
5,544 Posts
6,646 Respect +1

Run this on all players using

Code Snippet

Plaintext

array_thread(getPlayers(), ::reloading_monitor);

Code Snippet

Plaintext

reloading_monitor()
{
	while(1)
	{
		self.reloading = false;
		self waittill("reload_start");
		ammo = self getWeaponAmmoClip(self getCurrentWeapon()); //get their current ammo during the reload, probably 0
		self.reloading = true;
		while(ammo == self getWeaponAmmoClip(self getCurrentWeapon())) //wait for the ammo to change to something other than what we caught during the reload
			wait 0.00001;
	}
}

Then you can check if(self.reloading) or whatever is appropriate for the function you are using it in.

I use this in UGX Mod and it works perfectly fine.

Reply #7 on: June 27, 2014, 02:43:37 am

DidUknowiPwn
UGX Team Member
1,322 Posts
423 Respect +1

Quote from: treminaor on June 26, 2014, 10:44:23 pm

Run this on all players using

Code Snippet

Plaintext

array_thread(getPlayers(), ::reloading_monitor);

Code Snippet

Plaintext

reloading_monitor()
{
	while(1)
	{
		self.reloading = false;
		self waittill("reload_start");
		ammo = self getWeaponAmmoClip(self getCurrentWeapon()); //get their current ammo during the reload, probably 0
		self.reloading = true;
		while(ammo == self getWeaponAmmoClip(self getCurrentWeapon())) //wait for the ammo to change to something other than what we caught during the reload
			wait 0.00001;
	}
}

Then you can check if(self.reloading) or whatever is appropriate for the function you are using it in.

I remember seeing reload_start/reload_end ,=,
Edit: Nevermind no reload_end

Last Edit: June 27, 2014, 02:44:56 am by DidUknowiPwn

Marked as best answer by Ege115 12 years ago

Reply #8 on: June 27, 2014, 04:20:56 am

MakeCents
Scripter
1,895 Posts
791 Respect +1

This script will set a variable for the player, is_reloading, based on whether or not the player is currently reloading. I had two issues that I could not resolve. getting the sprint binding when it was shift was an issue, so I worked around it, and if you switch weapons too quickly that you end right back at the same weapon, it doesn't register, so I added a 3 second timer to stop if from setting reload true until the next time. I think I accounted for the other stuff that cancels reload though.

I left the print statements in the top code so you can see what it is doing and see that you have the option to do something depending of if the player finishes reloading or not.

You can just thread this in your nazi_zombie_mapname.gsc right above zombie mode

Code Snippet

Plaintext

    thread reloadWatch();
	/*--------------------
	 ZOMBIE MODE
	----------------------*/

Code Snippet

Plaintext

reloadWatch(){
	flag_wait("all_players_connected");
	players = get_players();
	for(i=0;i<players.size;i++){
		players[i].isreloading = 0;
		players[i] thread reloadStatus();
	}
}
reloadStatus(){
	while(1){
		self waittill("reload_start");
		self.reloading = 1;
		self thread playerReloading();
		self waittill("reloaded");
		self.reloading = 0;
		wait(.05);
	}
}
playerReloading(){
	self endon("reloaded");
	gun = self getcurrentweapon();
	ammo = self getcurrentweaponclipammo();
	self thread playerTimer(3);//3 second fail safe
	while(!(self playerButtonCancel()) && !(self playerWeaponCancel()) && !(ammo < self getcurrentweaponclipammo()) && gun == self getcurrentweapon() && !(self getstance() == "prone") ){
 
		wait(.05);
	}
	if(ammo < self getcurrentweaponclipammo() && gun == self getcurrentweapon() ){
		self iprintlnbold("I finished reloading");
	}else{
		self iprintlnbold("Reloading must have been interupted");
	}
	self notify("reloaded");
}
playerTimer(timer){
	self endon("reloaded");
	wait(timer); //added due to bug with switching weapons too fast.
	self iprintlnbold("Reloading too long, must be bug");
	self notify("reloaded");
}
playerButtonCancel(){
	buttons = [];
	buttons[0] = "[{weapprev}]";
	buttons[1] = "[{weapnext}]";
	buttons[2] = "[{+breath_sprint}]";//returns Shift, instead of shift, but != to "shift"?
	buttons[3] = "[{+sprint}]";
	for(b=0;b<buttons.size;b++){
		if(self Buttonpressed(buttons[b]) || self Buttonpressed("shift")){
			return true;
		}	
	}
	return false;
}
playerWeaponCancel(){
	if(self isthrowingGrenade() || self ismeleeing() || self isfiring()){
		return true;
	}
}

I also included a stand alone _isReloading.gsc down below if you rather add it below maps\_zombiemode::main();

Code Snippet

Plaintext

/*--------------------
	 ZOMBIE MODE
	----------------------*/
	[[level.DLC3.weapons]]();
	[[level.DLC3.powerUps]]();
	maps\_zombiemode::main();
	maps\_isReloading::init();

Code Snippet

Plaintext

#include common_scripts\utility; 
#include maps\_utility;
#include maps\_zombiemode_utility; 

init(){
	flag_wait("all_players_connected");
	players = get_players();
	for(i=0;i<players.size;i++){
		players[i].isreloading = 0;
		players[i] thread reloadStatus();
	}
}
reloadStatus(){
	while(1){
		self waittill("reload_start");
		self.is_reloading = 1;
		self thread playerReloading();
		self waittill("reloaded");
		self.is_reloading = 0;
		wait(.05);
	}
}
playerReloading(){
	self endon("reloaded");
	gun = self getcurrentweapon();
	ammo = self getcurrentweaponclipammo();
	self thread playerTimer(3);//3 second fail safe
	while(!(self playerButtonCancel()) && !(self playerWeaponCancel()) && !(ammo < self getcurrentweaponclipammo()) && gun == self getcurrentweapon() && !(self getstance() == "prone") ){
		wait(.05);
	}
	if(ammo < self getcurrentweaponclipammo() && gun == self getcurrentweapon() ){
		// self iprintlnbold("I finished reloading");
	}else{
		// self iprintlnbold("Reloading must have been interupted");
	}
	self notify("reloaded");
}
playerTimer(timer){
	self endon("reloaded");
	wait(timer); //added due to bug with switching weapons too fast.
	// self iprintlnbold("Reloading too long, must be bug");
	self notify("reloaded");
}
playerButtonCancel(){
	buttons = [];
	buttons[0] = "[{weapprev}]";
	buttons[1] = "[{weapnext}]";
	buttons[2] = "[{+breath_sprint}]";//returns Shift, instead of shift, but != to "shift"?
	buttons[3] = "[{+sprint}]";
	for(b=0;b<buttons.size;b++){
		if(self Buttonpressed(buttons[b]) || self Buttonpressed("shift")){
			return true;
		}	
	}
	return false;
}
playerWeaponCancel(){
	if(self isthrowingGrenade() || self ismeleeing() || self isfiring()){
		return true;
	}
}

Last Edit: June 27, 2014, 07:44:11 pm by MakeCents

Reply #9 on: June 30, 2014, 06:20:26 pm

Ege115
Scripter
517 Posts
161 Respect +1

Hi, I have finally tested and your script worked perfect makecents. It was hard for me to decide which script I was going to use in this topic. xD

This almost deserves a tutorial makecents.

thanks for the script.

Reply #10 on: June 30, 2014, 08:29:11 pm

MakeCents
Scripter
1,895 Posts
791 Respect +1

Quote from: Ege115 on June 30, 2014, 06:20:26 pm

Hi, I have finally tested and your script worked perfect makecents. It was hard for me to decide which script I was going to use in this topic. xD

This almost deserves a tutorial makecents.
thanks for the script.

Cool! Glad it worked for you.

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha



	Has the ability to issue warnings to users, edit and remove posts from the forum and to move topics to other boards. Upholds the rules of the forum. Moderates Chat Rooms.

UGX-Mods Login

Check if the player is reloading