Script Loop Problem in Scripting

Created on: June 29, 2015, 05:43:34 am

Code Snippet

Plaintext

grief_damage()
{
	players = get_players();
	for(i=0;i<players.size;i++)
	{
  		players[i] thread grenade_damage();
  		players[i] thread griefing();
	}
}

Code Snippet

Plaintext

griefing()
{
	level._effect["grief_shock"] = loadfx( "fx_bullet_flesh_hit" );
	while(1)
	{
		players = get_players();
		for (i = 0; i < players.size; i++)
		{
			if( self islookingat(players[i]) && self isFiring() )
			{
				self thread griefing();
				self maps\_zombiemode_score::add_to_player_score( 10 );
				PlayFX( level._effect["grief_shock"], players[i].origin );
				players[i] setMoveSpeedScale( .3 );
				wait( 1.5 );
				players[i] setMoveSpeedScale( 1 );
				break;
			}
			else if( self islookingat(players[i]) && self isMeleeing() && self istouching(players[i]) )
			{
				self thread griefing();
				iprintln(vectorToAngles(self.origin - players[i].origin));
				self maps\_zombiemode_score::add_to_player_score( 10 );
				if( isDefined( self.has_altmelee ) && self.has_altmelee )
				{
					players[i] setVelocity( vectorToAngles( self.origin - players[i].origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
				}
				players[i] setVelocity( vectorToAngles( self.origin - players[i].origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
				PlayFX( level._effect["grief_shock"], players[i].origin );
				players[i] setMoveSpeedScale( .3 );
				wait( 1.5 );
				players[i] setMoveSpeedScale( 1 );
				break;
			}
		}
		wait(0.05);
	}
}

For some reason, the code seems to loop quite a few times (you're suppose to gain 10 points when you shoot someone, but you earn like 30 +10's) even though I have a break and after shooting someone about 3 times the game crashes.

Reply #1 on: June 29, 2015, 07:19:29 am

daedra descent
Community Daedra
2,789 Posts
230 Respect +1

Code Snippet

Plaintext

self thread griefing();

This. Your creating a new instance of the same function everytime you damage someone. Remove it.

Last Edit: June 29, 2015, 07:19:53 am by daedra descent

Reply #2 on: June 29, 2015, 07:20:09 am

BluntStuffy
Scripter Elite
1,186 Posts
1,332 Respect +1

You're making all players thread the function, and then you get all players again.
The players that threads it is in the function twice, might need a check like

Code Snippet

Plaintext

if( players[i] == self )

EDIT: And even more what DD said, missed that..

Quote

... but you earn like 30 +10's) even though I have a break and after shooting ...

You are only breaking out of the for() loop, not the while() loop..

Last Edit: June 29, 2015, 07:32:53 am by BluntStuffy

Reply #3 on: June 29, 2015, 05:23:47 pm

DidUknowiPwn
UGX Team Member
1,322 Posts
423 Respect +1

~~isFiring is also for AI only.~~

My bad

Code Snippet

Plaintext

test()
{
	self endon("death");
	self endon("disconnect");
 
	while(true)
	{
		if(self IsFiring())
			IPrintLnBold("I'm shooting");
		else
			IPrintLn("Nah");
		wait 0.05;
	}
}

Last Edit: June 29, 2015, 06:48:10 pm by DidUknowiPwn

Reply #4 on: June 29, 2015, 06:38:13 pm

MakeCents
Scripter
1,895 Posts
791 Respect +1

I see what your going for, and if you take the while loop out or you remove the recursive call, your still gonna run into issues. Maybe not the crash. You probably want to thread some other functions that end on a notification, which would be notified right before threading. Otherwise the speed is going to be set back awkwardly.

I don't think your level._effect["grief_shock"] = loadfx( "fx_bullet_flesh_hit" ); needs to be set every time either.
I haven't testing any of this, but I think it would flow better...?

Code Snippet

Plaintext

grief_damage()
{
	level._effect["grief_shock"] = loadfx( "fx_bullet_flesh_hit" );
	players = get_players();
	for(i=0;i<players.size;i++)
	{
  		players[i] thread grenade_damage();
  		players[i] thread griefing();
	}
}
griefing()
{
 
	while(1)
	{
		// self waittill("weapon_fired");//you could add this too, but not sure what need changed for melee
		players = get_players();
		for (i = 0; i < players.size; i++)
		{
			if( self islookingat(players[i]) && self isFiring() )
			{
				self notify("shooting_player");
				self thread ShootingPlayer(players[i]);
				break;
			}
			else if( self islookingat(players[i]) && self isMeleeing() && self istouching(players[i]) )
			{
				self notify("stabbing_player");
				self thread ShootingPlayer(players[i]);
				break;
			}
		}
		wait(0.05);//get rid of this if the waittill("weapon_fired") works
	}
}
ShootingPlayer(player){
	self endon("disconnect");
	self endon("shooting_player");
	self maps\_zombiemode_score::add_to_player_score( 10 );
	PlayFX( level._effect["grief_shock"], player.origin );
	player setMoveSpeedScale( .3 );
	wait( 1.5 );
	player setMoveSpeedScale( 1 );
}
StabbingPlayer(player){
	self endon("disconnect");
	self endon("stabbing_player");
	iprintln(vectorToAngles(self.origin - player.origin));
	self maps\_zombiemode_score::add_to_player_score( 10 );
	if( isDefined( self.has_altmelee ) && self.has_altmelee )
	{
		player setVelocity( vectorToAngles( self.origin - player.origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
	}
	player setVelocity( vectorToAngles( self.origin - player.origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
	PlayFX( level._effect["grief_shock"], player.origin );
	player setMoveSpeedScale( .3 );
	wait( 1.5 );
	player setMoveSpeedScale( 1 );
	break;
}

You could also add that waittil("weapon_fired")?

Last Edit: June 29, 2015, 06:42:26 pm by MakeCents

Reply #5 on: June 29, 2015, 07:08:58 pm

Code Snippet

Plaintext

griefing()
{
	while(1)
	{
		players = get_players();
		for (i = 0; i < players.size; i++)
		{
			if( self islookingat(players[i]) && self AttackButtonPressed() && self GetCurrentWeaponClipAmmo() > 0 )
			{
				weapon = self getcurrentweapon();
				if(players[i].maxhealth > players[i].health)
				{
					self maps\_zombiemode_score::add_to_player_score( 10 );
				}
				players[i] thread slowdown(weapon);
				wait WeaponFireTime( self GetCurrentWeapon() );
			}
			else if( self islookingat(players[i]) && self MeleeButtonPressed() && self istouching(players[i]) )
			{
				iprintln(vectorToAngles(self.origin - players[i].origin));
				if(players[i].maxhealth > players[i].health)
				{
					self maps\_zombiemode_score::add_to_player_score( 10 );
				}
				if( isDefined( self.has_altmelee ) && self.has_altmelee )
				{
					players[i] setVelocity( vectorToAngles( self.origin - players[i].origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
				}
				players[i] setVelocity( vectorToAngles( self.origin - players[i].origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
				players[i] thread slowdown();
				wait 1;
			}
		}
		/*zombs = getaispeciesarray("axis");
		for(i=0;i<zombs.size;i++)
		{
			if( self islookingat(zombs[i]) && self AttackButtonPressed() )
			{
				weapon = self getcurrentweapon();
				self maps\_zombiemode_score::add_to_player_score( 10 );
				self thread slowdown(weapon);
				zombs[i] thread slowdown();
				wait WeaponFireTime( self GetCurrentWeapon() );
			}
		}*/
		wait(0.05);
	}
}

This is what I have now, I fixed the crashing.
The melee part doesn't seem to do anything but the shooting part works.
Another problem is that islookingat() only seems to notice if you are looking at something up to a certain distance (300ish units), is there a way to extend this range?

Reply #6 on: June 29, 2015, 09:44:09 pm

daedra descent
Community Daedra
2,789 Posts
230 Respect +1

Quote from: jbird on June 29, 2015, 07:08:58 pm

Code Snippet

Plaintext

griefing()
{
	while(1)
	{
		players = get_players();
		for (i = 0; i < players.size; i++)
		{
			if( self islookingat(players[i]) && self AttackButtonPressed() && self GetCurrentWeaponClipAmmo() > 0 )
			{
				weapon = self getcurrentweapon();
				if(players[i].maxhealth > players[i].health)
				{
					self maps\_zombiemode_score::add_to_player_score( 10 );
				}
				players[i] thread slowdown(weapon);
				wait WeaponFireTime( self GetCurrentWeapon() );
			}
			else if( self islookingat(players[i]) && self MeleeButtonPressed() && self istouching(players[i]) )
			{
				iprintln(vectorToAngles(self.origin - players[i].origin));
				if(players[i].maxhealth > players[i].health)
				{
					self maps\_zombiemode_score::add_to_player_score( 10 );
				}
				if( isDefined( self.has_altmelee ) && self.has_altmelee )
				{
					players[i] setVelocity( vectorToAngles( self.origin - players[i].origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
				}
				players[i] setVelocity( vectorToAngles( self.origin - players[i].origin ) ); // Not tested, you'll have to play around with this. Most likely won't push the player in the correct direction.
				players[i] thread slowdown();
				wait 1;
			}
		}
		/*zombs = getaispeciesarray("axis");
		for(i=0;i<zombs.size;i++)
		{
			if( self islookingat(zombs[i]) && self AttackButtonPressed() )
			{
				weapon = self getcurrentweapon();
				self maps\_zombiemode_score::add_to_player_score( 10 );
				self thread slowdown(weapon);
				zombs[i] thread slowdown();
				wait WeaponFireTime( self GetCurrentWeapon() );
			}
		}*/
		wait(0.05);
	}
}

You fixed it or one of our suggestions worked?

Anyway this might be why melee doesn't work:

Code Snippet

Plaintext

self istouching(players[i])

I doubt knifing someone counts as "touching" them in CoD.

As for isLookingAt(), don't think you can change it. Honestly i think you should just do a <player> waittill("damage", attacker) for this. Less code and it would fix the isLookingAt bug.

Reply #7 on: June 29, 2015, 09:50:36 pm

Quote from: daedra descent on June 29, 2015, 09:44:09 pm

You fixed it or one of our suggestions worked?

Anyway this might be why melee doesn't work:
Code Snippet
Plaintext
self istouching(players[i])
I doubt knifing someone counts as "touching" them in CoD.

As for isLookingAt(), don't think you can change it. Honestly i think you should just do a <player> waittill("damage", attacker) for this. Less code and it would fix the isLookingAt bug.

I fixed it, I rewrote it so it doesn't need break functions and doesn't re-thread itself.

The if line says

Code Snippet

Plaintext

else if( self islookingat(players[i]) && self MeleeButtonPressed() && self istouching(players[i]) )

So you have to be touching someone AND meleeing for it take effect because if I didn't have the istouching() then it would happen when you melee someone while looking at them from any range instead of only melee range.

I tried a waittill "damage" but it doesn't work because players don't actually damage other players.

Reply #8 on: June 29, 2015, 10:04:11 pm

BluntStuffy
Scripter Elite
1,186 Posts
1,332 Respect +1

Quote from: jbird on June 29, 2015, 09:50:36 pm

I fixed it, I rewrote it so it doesn't need break functions and doesn't re-thread itself.

And who was the one telling you it was doing that? that was DD, so technically he fixed it

Reply #9 on: June 29, 2015, 11:59:35 pm

Quote from: MakeCents on June 29, 2015, 06:38:13 pm

You could also add that waittil("weapon_fired")?

Isn't "weapon_fired" only for tanks though? At least that's what Sparky said http://gyazo.com/451b54c99532d58c1d93accd983eefa7

Reply #10 on: June 30, 2015, 12:02:38 am

Ege115
Scripter
517 Posts
161 Respect +1

The isFiring() function also returns true when you're meleeing.

Reply #11 on: June 30, 2015, 12:05:59 am

MakeCents
Scripter
1,895 Posts
791 Respect +1

Quote from: jbird on June 29, 2015, 11:59:35 pm

Isn't "weapon_fired" only for tanks though? At least that's what Sparky said http://gyazo.com/451b54c99532d58c1d93accd983eefa7

No.


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
Oil Rig Beta Access

UGX-Mods Login

Script Loop Problem