xSanchez78's Hintstrings in Scripts

Hey guys today i have something small but good
for you. This is my custom hintstring setup.
The purpose of this is to be able to have a hint
string that won't stop updating after 48 different
hinstrings have been set. This is kind of like
treminaor's hintstring fix, but it has a little
bit more, to make it more like the real hintstrings.

JUST SO YOU KNOW

yes this originally is from trem's hintstrings, but has a re-written
menufile and script to include more, which is why i claim it to be
a different topic. Don't care what you say about that tho.

xSanchez78's Hintstrings

Let's Get Started!

First open your hud.menu in root/mods/modname/ui.
If you dont have it in that folder, copy it from
root/raw/ui into there. Then open it. Find and
replace this

Code Snippet

Plaintext

	// Cursor hints
	menuDef
	{
		name			"Cursorhints"
		rect			0 70 40 40 HORIZONTAL_ALIGN_CENTER VERTICAL_ALIGN_CENTER
		fullScreen		0
		visible	when	 	( CHAPLIN_CHEAT_OFF && ( dvarString( mapname ) != "credits" ) );
 
		itemDef
		{
			name			"chRect"
			rect			0 0 40 40 // 64x64
			textscale		TEXTSIZE_SMALL
			textstyle		ITEM_TEXTSTYLE_SHADOWED
			ownerdraw		CG_CURSORHINT
			visible			1
			decoration
		}
	}

with this

Code Snippet

Plaintext

	// Cursor hints
	menuDef
	{
		name			"Cursorhints"
		rect			0 70 40 40 HORIZONTAL_ALIGN_CENTER VERTICAL_ALIGN_CENTER
		fullScreen		0
		visible	when	 	( CHAPLIN_CHEAT_OFF && ( dvarString( mapname ) != "credits" ) );
 
		itemDef
		{
			name			"chRect"
			rect			0 0 40 40 // 64x64
			textscale		TEXTSIZE_SMALL
			textstyle		ITEM_TEXTSTYLE_SHADOWED
			ownerdraw		CG_CURSORHINT
			visible			1
			decoration
		}
 
		itemDef
		{
			name			"xS78_hintstring_use"
			rect			0 0 0 0
			textscale		TEXTSIZE_SMALL
			textstyle		ITEM_TEXTSTYLE_SHADOWED
			textalign 		ITEM_ALIGN_CENTER
			exp text 		( dvarString( "xS78_hintstring_text_left" ) + KeyBinding( "+activate" ) + dvarString( "xS78_hintstring_text_right" ) )
			visible			when( dvarInt( "xS78_hintstring_use_vis" ) == 1 )
			decoration
		}
 
		itemDef
		{
			name			"xS78_hintstring_nouse"
			rect			0 0 0 0
			textscale		TEXTSIZE_SMALL
			textstyle		ITEM_TEXTSTYLE_SHADOWED
			textalign 		ITEM_ALIGN_CENTER
			exp text 		dvarString( "xS78_hintstring_text_nouse" )
			visible			when( dvarInt( "xS78_hintstring_nouse_vis" ) == 1 )
			decoration
		}
	}

Save it and close. Make sure in mod.csv
you call this:

Code Snippet

Plaintext

menufile,ui/hud.menu

Now open up _zombiemode_utility.gsc. At the top
put this in.

Code Snippet

Plaintext

//xSanchez78's Hintstrings
_setHintString( hint, radius )
{
	self thread maps\_xS78_hintstrings::xS78_SetHintString( hint, radius );
}

_setVisibleToPlayer( player )
{
	self maps\_xS78_hintstrings::xS78_setVisibleToPlayer( player );
}

_setVisibleToAll()
{
	self maps\_xS78_hintstrings::xS78_setVisibleToAll();
}

_setInvisibleToPlayer( player, show )
{
	self maps\_xS78_hintstrings::xS78_setInvisibleToPlayer( player, show );
}
//xSanchez78's Hintstrings

Now make a new file called _xS78_hintstrings.gsc.
Place this into it:

Code Snippet

Plaintext

#include common_scripts\utility; 
#include maps\_utility;
#include maps\_zombiemode_utility; 

xS78_SetHintString( string, radius )
{
	if( !isDefined( string ) )
	{
		return;
	}
	self notify( "new_hintstring" );
	self endon( "new_hintstring" );
	self SetHintString( "" );
	self SetCursorHint( "HINT_NOICON" );
	flag_wait( "all_players_connected" );
	if( !isDefined( self.PlayersVisibleTo ) ) 
	{
		self.PlayersVisibleTo = [];
		players = get_players();
		for( i = 0; i < players.size; i++ )
		{
			self.PlayersVisibleTo[ self.PlayersVisibleTo.size ] = players[i];
		}
	}
	while( isDefined( self ) )
	{
		players = get_players();
		for( i = 0; i < players.size; i++ )
		{
			if( players[i] TrigIsVisibleTo( self ) && ( ( !isDefined( radius ) && players[i] istouching( self ) ) || ( isDefined( radius ) && distance( players[i].origin, self.origin ) < radius ) ) )
			{
				players[i].hintstring_to_show = string;
				players[i] thread setHintString_show( self, string, radius );
			}
		}
		wait 0.1;
	}
}

TrigIsVisibleTo( trig )
{
	if( !isDefined( trig.PlayersVisibleTo ) )
	{
		return true;
	} 
	for( i = 0; i < trig.PlayersVisibleTo.size; i++ )
	{
		if( trig.PlayersVisibleTo[i] == self )
		{
			return true;
		}
	}
	return false;
}

setHintString_show( trig, string, radius )
{
	if( isDefined( self.lookingattrig ) && self.lookingattrig == trig )
	{
		return;
	}
	while( isDefined( trig ) && isDefined( self.hintstring_to_show ) && self.hintstring_to_show == string && ( ( !isDefined( radius ) && self istouching( trig ) ) || ( isDefined( radius ) && distance( self.origin, trig.origin ) < radius ) ) && self TrigIsVisibleTo( trig ) )
	{
		self.lookingattrig = trig;
		self hintstring_update( string, true );
		wait 0.001;
	}
	self.lookingattrig = undefined;
	self hintstring_update( string, false );
}

hintstring_update( line, show )
{
	if( !show )
	{
		self SetClientDvar( "xS78_hintstring_text_left", "" );
		self SetClientDvar( "xS78_hintstring_text_right", "" );
		self SetClientDvar( "xS78_hintstring_use_vis", 0 );
		self SetClientDvar( "xS78_hintstring_text_nouse", "" );
		self SetClientDvar( "xS78_hintstring_nouse_vis", 0 );
		return;
	}
	index = 0;
	has_use = false;
	for( i = 0; i < line.size; i ++ )
	{
		if( line[ i ] == "&" && line[ i + 1 ] == "&" && line[ i + 2 ] == "1" )
		{
			index = i;
			has_use = true;
		}
	}
	if( !has_use )
	{
		self SetClientDvar( "xS78_hintstring_text_left", "" );
		self SetClientDvar( "xS78_hintstring_text_right", "" );
		self SetClientDvar( "xS78_hintstring_use_vis", 0 );
		self SetClientDvar( "xS78_hintstring_text_nouse", string( line ) );
		self SetClientDvar( "xS78_hintstring_nouse_vis", 1 );
		return;
	}
	left = getSubStr( line, 0, index );
	right = getSubStr( line, index + 3, line.size );
	self SetClientDvar( "xS78_hintstring_text_left", string( left ) );
	self SetClientDvar( "xS78_hintstring_text_right", string( right ) );
	self SetClientDvar( "xS78_hintstring_use_vis", 1 );
	self SetClientDvar( "xS78_hintstring_text_nouse", "" );
	self SetClientDvar( "xS78_hintstring_nouse_vis", 0 );
}

xS78_setVisibleToPlayer( player )
{
	self.PlayersVisibleTo = [];
	self.PlayersVisibleTo[0] = player;
	self setVisibleToPlayer( player );
}

xS78_setVisibleToAll()
{
	self.PlayersVisibleTo = [];
	players = get_players();
	for( k = 0; k < players.size; k++ )
	{
		self.PlayersVisibleTo[ self.PlayersVisibleTo.size ] = players[k];
	}
	self setVisibleToAll();
}

xS78_setInvisibleToPlayer( player, show )
{
	if( !isDefined( self.PlayersVisibleTo ) )
	{
		self.PlayersVisibleTo = [];
	}
	if( !isDefined( show ) )
	{
		newarray = [];
		for( i = 0; i < self.PlayersVisibleTo.size; i++ )
		{
			if( self.PlayersVisibleTo[i] != player )
			{
				newarray[ newarray.size ] = self.PlayersVisibleTo[i];
			}
		}
		self.PlayersVisibleTo = newarray;
		self setInvisibleToPlayer( player );
	}
	else
	{
		if( show )
		{
			newarray = [];
			for( i = 0; i < self.PlayersVisibleTo.size; i++ )
			{
				if( self.PlayersVisibleTo[i] != player )
				{
					newarray[ newarray.size ] = self.PlayersVisibleTo[i];
				}
			}
			self.PlayersVisibleTo = newarray;
			self setInvisibleToPlayer( player, true );
		}
		else
		{
			already_visible = false;
			for( i = 0; i < self.PlayersVisibleTo.size; i++ )
			{
				if( self.PlayersVisibleTo[i] == player )
				{
					already_visible = true;
				}
			}
			if( !already_visible )
			{
				self.PlayersVisibleTo[ self.PlayersVisibleTo.size ] = player;
			}
			self setInvisibleToPlayer( player, false );
		}
	}
}

Now to apply the hintstring setup,
first make sure that each script you
use this in has this at the top

Code Snippet

Plaintext

#include maps\_zombiemode_utility;

Most zombiemode scripts have that
at the top already. Now all you have
to do is go into each script and find
these for functions:

Code Snippet

Plaintext

SetHintString()
SetInvisibleToPlayer()
SetVisibleToPlayer()
SetVisibleToAll()

and replace them with this:

Code Snippet

Plaintext

_SetHintString()
_SetInvisibleToPlayer()
_SetVisibleToPlayer()
_SetVisibleToAll()

Very simple. You don't have to change the
arguments in them or anything, just simply
add an underscore in front of the function.

NOTES:

   - UseTriggerRequireLookAt() will not make the
     hintstrings dissapear when you look away. They
     will always show as long as you are touching the trigger.

   - This is scripted checking systems, not run by the
     engine. That means that sometimes your trigger may
     just in a wierd place or wierd shape and the hintstring
     may not show up because even though you can use the
     trigger and the default string would show, doesn't mean
     that the function "istouching()" will return true. I have
     made a way for you to add a radius for your trigger though.
     Instead of using just "_SetHintString( string );", for the
     triggers that don't seem to work, just add this:
     "_SetHintString( string, radius );". The radius can be
     set to anything and then it will check if you are close
     enough based on the radius to see the trigger. Experiment
     and see which radiuses work best for your trigger!

   - Localized strings do NOT work! If you put in a localized
     string it most likely wont show up ( idk what happens
     its been a while since i tried ) but it most likely wont
     work so dont even try. Things like &"ZOMBIE_FLAMES_UNAVAILABLE"
     have to be replaced with a normal string like: "The power must be activated first"

That's all guys, hope you enjoy. By the way for those
wondering: some people might not trust this since my
last tutorial was released un-tested. Well trust me, this
HAS been tested. I made this during christmas break ( 5 months
ago ) and it was worked every since, so dont worry. Thanks,
remember to credit me, and peace out.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
Famous User

UGX-Mods Login

xSanchez78's Hintstrings