Note:

//chris_p - added dogs to the scoring
player_add_points( event, mod, hit_location ,is_dog)
{
	if( level.intermission )
	{
		return;
	}

	if( !is_player_valid( self ) )
	{
		return;
	}
 
	points = 0;

	switch( event )
	{
		case "death":
			points = level.zombie_vars["zombie_score_kill"]; 
			points += player_add_points_kill_bonus( mod, hit_location );
			if(IsDefined(self.kill_tracker))
			{
				self.kill_tracker++;
			}
			else
			{
				self.kill_tracker = 1;
			}
			//stats tracking
			self.stats["kills"] = self.kill_tracker;

			if( mod == "MOD_MELEE" && self hasperk( "specialty_altmelee" ) )
			{	
				self achievement_notify( "DLC3_ZOMBIE_BOWIE_KILLS" );
			}

			if( level.zombie_vars["zombie_powerup_insta_kill_on"] == 1 && mod == "MOD_UNKNOWN" )
			{
				points = points * 2;
			}

			break; 
 
		case "damage":
			points = level.zombie_vars["zombie_score_damage"]; 
			break; 
 
		case "damage_ads":
			points = Int( level.zombie_vars["zombie_score_damage"] * 1.25 ); 
			break;
 
		default:
			assertex( 0, "Unknown point event" ); 
			break; 
	}

	points = round_up_to_ten( points ) * level.zombie_vars["zombie_point_scalar"];
 

	self.score += points; 
	self.score_total += points;
	//stat tracking
	self.stats["score"] = self.score_total;

	self set_player_score_hud(); 
//	self thread play_killstreak_vo();
}

Edit: So it looks like my theory was correct that the HUD ownerdraw is rounded up automatically.
(Image removed from quote.)

yea, so the hud would "say" 950, but your actual score would be 945, right?

Looks that way yup.