[Tutorial] Dynamic Light in Mapping

Dynamic Light Tutorial

*For the lazy people there is a link a the bottom for the prefab.

Radiant Part:

Step 1:

Right click in the 2d grid to add a rope.

Step 2:

Place the rope halfway through the ceiling.

Step 3:

Right click in the 2d grid again and add a info > null

Step 4:

Place the info_null under the rope.

Step 5:

Select the rope first and then the info_null and press “W” to connect them.

Step 6:

Add a script_model and choose the model “lights_tinhatlamp_on” *It can be any other model but I have chosen to use this one for the example.

Step 7:

Place the script model under the info_null

Step 8:

Select the info_null first and then the script_model and press “W” to connect them.

Step 9:

Give the script_model the following kvp:

Code Snippet

Plaintext

"script_noteworthy" "dyn_lamp"

Step 10:

Add a light and place it under the script_model.

Step 11:

Give the light the following kvps:

Code Snippet

Plaintext

"maxmove" "500"
"maxturn" "360"
"targetname" "dyn_light"
"exponent" "1"
"fov_inner" "40"
"fov_outer" "60"
"spawnflags" "22"
"def" "light_point_linear"
"radius" "400"
"_color" "1 1 1"
"intensity" "2"

*Change the spotlight specific settings to whatever you like. But make sure u don’t change the spawnflags.

Step 12:

Add a info_null and place it under/inside the light. Now select the light and then the info_null and press “W” to connect them.

And that’s it for the radiant part. Now we only need to add a simple script to make this all work.

Scripting Part:

Step 1:

Add the following line in your “nazi_zombie_mapname.gsc” and place in under DLC3_FX():

Code Snippet

Plaintext

level._effect["chair_light_fx"] = loadfx("env/light/fx_glow_hanginglamp");

Step 2:

Add the following line under maps\_zombiemode::main():

Code Snippet

Plaintext

thread dynamic_light();

Step 3:

Add the following code at the bottom:

Code Snippet

Plaintext

dynamic_light()
{
	lamp = getent("dyn_lamp","script_noteworthy");
	light = getent("dyn_light","targetname");

	if(!isdefined(light))
		return;
 
	light linkto(lamp);
 
	fx = spawn("script_model", lamp.origin);
	fx.angles = (90,0,0);
	fx setmodel("tag_origin");
	fx linkto(lamp);
	playfxontag(level._effect["chair_light_fx"],fx,"tag_origin");
 
	while(1)
	{	
		lamp physicslaunch ( lamp.origin, (randomintrange(-20,20),randomintrange(-20,20),randomintrange(-20,20)) );
		wait(randomfloatrange(10,15));
	}
}

Step 4:

Add the following line to your “mod.csv”:

Code Snippet

Plaintext

fx,fx,env/light/fx_glow_hanginglamp

And that's it!

Update:

If you want to have multiple lights, use this code instead:

Scripting Part Multiple Lights:

Step 1:

Add the following line in your “nazi_zombie_mapname.gsc” and place in under DLC3_FX():

Code Snippet

Plaintext

level._effect["chair_light_fx"] = loadfx("env/light/fx_glow_hanginglamp");

Step 2:

Add the following line under maps\_zombiemode::main():

Code Snippet

Plaintext

lamps = getentarray("dyn_lamp","script_noteworthy");
array_thread(lamps,::dynamic_light);

Step 3:

Add the following code at the bottom:

Code Snippet

Plaintext

dynamic_light()
{
	light = get_array_of_closest(self.origin,getEntArray("dyn_light","targetname"))[0];

	if(!isdefined(light))
		return;
 
	light linkto(self);
 
	fx = spawn("script_model", self.origin);
	fx.angles = (90,0,0);
	fx setmodel("tag_origin");
	fx linkto(self);
	playfxontag(level._effect["chair_light_fx"],fx,"tag_origin");
 
	while(1)
	{	
		self physicslaunch ( self.origin, (randomintrange(-20,20),randomintrange(-20,20),randomintrange(-20,20)) );
		wait(randomfloatrange(10,15));
	}
}

Step 4:

Add the following line to your “mod.csv”:

Code Snippet

Plaintext

fx,fx,env/light/fx_glow_hanginglamp

And that's for multiple lights.

Prefab

www.mediafire.com

~RDV

	Has shown excellence and experience in the area of custom mapping in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
Oil Rig Beta Access

UGX-Mods Login

[Tutorial] Dynamic Light