init()
{
	teddies = GetEntArray( "teddies","targetname" );//trigger targetname for all triggers
	level.teddy_num = teddies.size;
	array_thread( teddies,::TriggerUs );
}
TriggerUs(){
	self UseTriggerRequireLookAt();
	self SetCursorHint( "HINT_NOICON" );
	self waittill("trigger", player);
	playFx(level._effect["flare"], self.origin);
	player playlocalsound( "meteor_affirm" );
	level.teddy_num--;
	if(level.teddy_num<=0){
		if(!IsDefined( self.target )){
			iPrintLn("trigger with targetname kvp: " + self.targetname + " has no target");
			return;
		}
		if(IsDefined( self.script_flag )) flag_set( self.script_flag );
		targets = GetEntArray( self.target,"targetname" );
		if(targets.size>0) play_sound_at_pos("door_slide_open", targets[0].origin);
		for( i=0;i<targets.size;i++ ){
			targets[i] thread MoveMe();
		}
	}
}
MoveMe(){
	time = 1;
	if(IsDefined( self.script_transition_time)) time = self.script_transition_time;//for speed of this piece to move
	if(IsDefined( self.script_noteworthy ) && self.script_noteworthy == "clip"){
		wait(time-.1);//wait the time and delete the clip once opened
		self NotSolid( );
		self connectpaths();
		self delete();
	}else{
		self NotSolid( );
		self connectpaths();
		self MoveZ (-200, time);
	}	
}