This should work if you want them to have to destroy one then the other, and don't delete any models or anything. The flag wait isn't needed but won't hurt it. But if you want to be able to do either and want a model to disappear as well I would recommend using something else more like this:

AccessDoors(){
    doors = GetEntArray( "dust_door","targetname" );
    array_thread( doors,GetMyTrigs );
}
GetMyTrigs(){
    trigs = GetEntArray( self.target,"targetname" );//each trig multiple has damage checked on it, and is the target of the door for it
    self.count = trigs.size;
    array_thread( trigs,SetupDoor,self);
}
SetupDoor(door){
    self waittill("trigger");
    text = "";
    if(isDefined(self.script_string)) text = " ^1"+self.script_string;//define script_string for the trigger to adjust iprintlnbold
    iprintlnBold("^3BombSite" + text + " ^3Destroyed , Good Work Mate !");
    if(IsDefined( self.target )){
        model = getent(self.target, "targetname");//you could also not use a trigger and make the model candamage, but that is different
        //playfx(level._effect[fx], model.origin);//maybe play explosion or something
        model delete();
    }
    door.count = door.count - 1;
    if(door.count<=0){
        play_sound_at_pos("door_slide_open", door.origin);
	iprintlnBold("You Opened The Ending Door , Good Job");
        door ConnectPaths( );//so the zombies can go through it after opened
        door NotSolid( );//so the player doesn't get stuck
        if(IsDefined( door.script_vector ))
            door MoveTo( door.origin + door.script_vector,1 );
        else
            door MoveZ( -900,1 );//your time was really slow
    }
}

In this setup, completely untested, just a theory, you would make your triggers the target of the door and any ents that you want to disappear when a trigger is triggered the target of that trigger. This should work for as many doors as you want and for as many triggers as you want per door.

self.target

trigs = GetEntArray( self.target,"targetname" ); //each trig multiple has damage checked on it, and is the target of the door for it

You could make the trigger be trigger_damage or hurt (seriously, for the life of me I cant remember this) and then just do check for what weapon player has

if(player hasWeapon("c4"))

Good luck. I'm not following your first comment.

You can adjust what damages the trigger by selecting the check boxes you don't want to trigger it, (trigger_damage)

hitman i think that doesn't define which damage the trigger is getting still dk

   shoot_me = getEnt("tim_a", "targetname");   // this is the First trigger that you toss an c4

I was looking at this, so I thought you meant only C4 damage would trigger the trigger, not like grenades and such

should really check "current" weapon, or follow what the grenade type weapon that was thrown is rather than "hasWeapon" if you were to do your method, just as a note

Otherwise grenades would trigger it too, as you could still "have" the c4, and i think if you havae 0 ammo after the throw, hasWepaon returns false ( i think, as i think i had this issue with the shield, had to use isDefined( hasWeapon() ) ) etc

Its actually not really possible to be 100 percent using either. You can throw a grenade and switch to c4 and fake it too. If 100 percent is desired, you would need to check another way, either by a use trigger, or something else.

Yeah, perhaps tracking if the c4 location is close enough to the trigs maybe. That prob would work too. Just not current weapon or has weapon, if you want 100 percent.