Hitmarker Script? in Help Desk

Created on: October 10, 2014, 10:53:38 pm

Hey Guys

Does anyone have a script for hitmarker? When yes can i got it?

Thx

MrDunlop4

Reply #1 on: October 24, 2014, 08:54:47 am

FATKIDSLOV3CAK3
Donator ♥
169 Posts
21 Respect +1

i would also like this

Reply #2 on: October 24, 2014, 09:52:47 am

RamboBadass
Community Mapper
927 Posts
352 Respect +1

I will 3rd this ... Someone please hook us up! Lol

Reply #3 on: October 24, 2014, 11:26:01 am

BluntStuffy
Community Scripter Elite
1,187 Posts
1,404 Respect +1

never tried, but maybe you can use this somehow:

maps\_damagefeedback.gsc

Reply #4 on: October 24, 2014, 03:25:53 pm

PROxFTW
Community Scripter
214 Posts
84 Respect +1

Here try this out. Note: The sound doesn't seem to work and probably because either I don't have it in the mod.csv or it is very quiet but I couldn't find the sound file for the hit marker so if you want that you will have to do that part yourself.
First copy _damagefeedback.gsc into mods/Mapname/maps
Now replace everything in that gsc with

Code Snippet

Plaintext

// MikeD (12/17/2007): Not called anywhere
init()
{
	//precacheShader( "damage_feedback" );
 
	//if ( getDvar( "scr_damagefeedback" ) == "" )
	//	setDvar( "scr_damagefeedback", "0" );

	//if ( !getDvarInt( "scr_damagefeedback" ) )
	//	return;

	self.hud_damagefeedback = newHudElem( self );
	self.hud_damagefeedback.alignX = "center";
	self.hud_damagefeedback.alignY = "middle";
	self.hud_damagefeedback.horzAlign = "center";
	self.hud_damagefeedback.vertAlign = "middle";
	self.hud_damagefeedback.y = 12;
	self.hud_damagefeedback.alpha = 0;
	self.hud_damagefeedback.archived = true;
	self.hud_damagefeedback setShader( "damage_feedback", 24, 48 );
}

monitorDamage()
{
	//if ( !getDvarInt( "scr_damagefeedback" ) )
	//	return;
	self.damageInit = true;

	for ( ;; )
	{
		self waittill( "damage", amount, attacker );
 
		if ( IsPlayer( attacker ) )
			attacker updateDamageFeedback();
	}
}

updateDamageFeedback()
{
	//if ( !IsPlayer( self ) )
	//	return;
 
	self playlocalsound( "SP_hit_alert" );
 
	self.hud_damagefeedback.alpha = 1;
	self.hud_damagefeedback fadeOverTime( 1 );
	self.hud_damagefeedback.alpha = 0;
}

Next in mapname.gsc find

Code Snippet

Plaintext

init() {  }

and below

Code Snippet

Plaintext

maps\_zombiemode::main();

add

Code Snippet

Plaintext

level thread HitTest();

And above

Code Snippet

Plaintext

maps\_zombiemode::main();

add

Code Snippet

Plaintext

precacheShader( "damage_feedback" );

And at the bottom of mapname.gsc add

Code Snippet

Plaintext

HitTest()
{
	for( i = 0; i < GetPlayers().size; i++ )
		GetPlayers()[i] thread maps\_damagefeedback::init();
	while( 1 )
	{
		ai = GetAiArray( "axis" );
		for( i = 0; i < ai.size; i++ )
			if( !IsDefined( ai[i].damageInit ) )
				ai[i] thread maps\_damagefeedback::monitorDamage();
		wait .01;
	}
}

Note: Don't forget to check _damagefeedback.gsc when you build your mod

Reply #5 on: October 24, 2014, 04:34:35 pm

FATKIDSLOV3CAK3
Donator ♥
169 Posts
21 Respect +1

Quote from: PROxFTW on October 24, 2014, 03:25:53 pm

Note: Don't forget to check _damagefeedback.gsc when you build your mod

thanks man will try this out in abit

Last Edit: October 24, 2014, 04:35:12 pm by FATKIDSLOV3CAK3

Reply #6 on: October 25, 2014, 04:49:01 pm

chromastone10
Community Mapper
840 Posts
265 Respect +1

Quote from: PROxFTW on October 24, 2014, 03:25:53 pm

Code Snippet

Plaintext

// MikeD (12/17/2007): Not called anywhere
init()
{
	//precacheShader( "damage_feedback" );
 
	//if ( getDvar( "scr_damagefeedback" ) == "" )
	//	setDvar( "scr_damagefeedback", "0" );

	//if ( !getDvarInt( "scr_damagefeedback" ) )
	//	return;

	self.hud_damagefeedback = newHudElem( self );
	self.hud_damagefeedback.alignX = "center";
	self.hud_damagefeedback.alignY = "middle";
	self.hud_damagefeedback.horzAlign = "center";
	self.hud_damagefeedback.vertAlign = "middle";
	self.hud_damagefeedback.y = 12;
	self.hud_damagefeedback.alpha = 0;
	self.hud_damagefeedback.archived = true;
	self.hud_damagefeedback setShader( "damage_feedback", 24, 48 );
}

monitorDamage()
{
	//if ( !getDvarInt( "scr_damagefeedback" ) )
	//	return;
	self.damageInit = true;

	for ( ;; )
	{
		self waittill( "damage", amount, attacker );
 
		if ( IsPlayer( attacker ) )
			attacker updateDamageFeedback();
	}
}

updateDamageFeedback()
{
	//if ( !IsPlayer( self ) )
	//	return;
 
	self playlocalsound( "SP_hit_alert" );
 
	self.hud_damagefeedback.alpha = 1;
	self.hud_damagefeedback fadeOverTime( 1 );
	self.hud_damagefeedback.alpha = 0;
}

Next in mapname.gsc find

Code Snippet

Plaintext

init() {  }

and below

Code Snippet

Plaintext

maps\_zombiemode::main();

add

Code Snippet

Plaintext

level thread HitTest();

And above

Code Snippet

Plaintext

maps\_zombiemode::main();

add

Code Snippet

Plaintext

precacheShader( "damage_feedback" );

And at the bottom of mapname.gsc add

Code Snippet

Plaintext

HitTest()
{
	for( i = 0; i < GetPlayers().size; i++ )
		GetPlayers()[i] thread maps\_damagefeedback::init();
	while( 1 )
	{
		ai = GetAiArray( "axis" );
		for( i = 0; i < ai.size; i++ )
			if( !IsDefined( ai[i].damageInit ) )
				ai[i] thread maps\_damagefeedback::monitorDamage();
		wait .01;
	}
}

Note: Don't forget to check _damagefeedback.gsc when you build your mod

this doesnt work coop, when another player shoots or damages a zombie, the hitmarker appears on everyone's screen

Reply #7 on: October 25, 2014, 05:08:43 pm

PROxFTW
Community Scripter
214 Posts
84 Respect +1

Quote from: chromastone10 on October 25, 2014, 04:49:01 pm

this doesnt work coop, when another player shoots or damages a zombie, the hitmarker appears on everyone's screen

Here chroma, try this and see if this makes a difference. Replace _damagefeedback.gsc with

Code Snippet

Plaintext

#include maps\_hud_util;
// MikeD (12/17/2007): Not called anywhere
init()
{
	//precacheShader( "damage_feedback" );
 
	//if ( getDvar( "scr_damagefeedback" ) == "" )
	//	setDvar( "scr_damagefeedback", "0" );

	//if ( !getDvarInt( "scr_damagefeedback" ) )
	//	return;

	self.hud_damagefeedback = self CreateRectangle( "", "", 0, 0, 24, 48, 1, ( 1, 1, 1 ), 0, "damage_feedback" );
}

CreateRectangle( Align, Relative, X, Y, Width, Height, Sort, Color, Alpha, Shader )
{
	Box = NewClientHUDElem( self );
	Box.ElemType = "bar";
	if( !level.splitscreen )
	{
		Box.X = -2;
		Box.Y = -2;
	}
	Box.Width = Width;
	Box.Height = Height;
	Box.Align = Align;
	Box.Relative = Relative;
	Box.XOffset = 0;
	Box.YOffset = 0;
	Box.Children = [];
	Box.Sort = Sort;
	if( IsDefined( Color ) )
		Box.Color = Color;
	Box.Alpha = Alpha;
	Box.Shader = Shader;
	Box SetParent( level.UIParent );
	Box SetShader( Shader, Width, Height );
	Box.Hidden = false;
	Box SetPoint( Align, Relative, X, Y );
	return Box;
}

monitorDamage()
{
	//if ( !getDvarInt( "scr_damagefeedback" ) )
	//	return;
	self.damageInit = true;

	for ( ;; )
	{
		self waittill( "damage", amount, attacker );
 
		if ( IsPlayer( attacker ) )
			attacker updateDamageFeedback();
	}
}

updateDamageFeedback()
{
	//if ( !IsPlayer( self ) )
	//	return;
 
	self playlocalsound( "MP_hit_alert" );
 
	self.hud_damagefeedback.alpha = 1;
	self.hud_damagefeedback fadeOverTime( 1 );
	self.hud_damagefeedback.alpha = 0;
}

and then in mapname.gsc replace

Code Snippet

Plaintext

HitTest(){ }

with

Code Snippet

Plaintext

HitTest()
{
	flag_wait( "all_players_connected" );
        wait 1;
	for( i = 0; i < GetPlayers().size; i++ )
		GetPlayers()[i] thread maps\_damagefeedback::init();
	while( 1 )
	{
		ai = GetAiArray( "axis" );
		for( i = 0; i < ai.size; i++ )
			if( !IsDefined( ai[i].damageInit ) )
				ai[i] thread maps\_damagefeedback::monitorDamage();
		wait .01;
	}
}

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
Oil Rig Beta Access

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

Hitmarker Script?