Better Kick and Walking in Scripting

Hello, today im releaseing the better kick and walking script i have recently made.

The Viewmodel will rotate dependent on the direction you are moving and when you shoot you get a randomized kick that will move your weapon slightly.

Adding the script:
--------------------------------------------------------------

First create a new GSC and add the following script into the file:

Code Snippet

Plaintext

#include common_scripts\utility; 
#include maps\_utility;
#include maps\_zombiemode_utility; 

init()
{
	level.kickbackmax = .4;
	level.kickbackmin = .2;
	level.kicksidemax = .3;
	level.kicksidemin = .1;	

	players = GetPlayers();
	array_thread(players,::walking);
	array_thread(players,::kick_watch);
}

walking()
{
	self endon("disconnect");
	for(;;)
	{
		if(!self adsButtonPressed())
		{
			self SetClientDvar("bg_bobAmplitudeStanding",".1 0.01");
			self SetClientDvar("bg_bobAmplitudeducking",".1 0.01");
			if(self GetStance() == "prone")
				self SetClientDvar("cg_gun_rot_minspeed", 0);
			else
				self SetClientDvar("cg_gun_rot_minspeed", -1000);
			rotvar = self getvelocity() * anglestoright(self GetPlayerAngles());
			rotvar = rotvar[0] + rotvar[1] + rotvar[2];
			rotvar = int(rotvar/20);
			self SetClientDvar("cg_gun_rot_r", rotvar);
		}
		else
		{
			self SetClientDvar("bg_bobAmplitudeStanding","0.01 0.001");
			self SetClientDvar("bg_bobAmplitudeducking","0.01 0.001");
		}
		wait(0.1);
	}
}

kick_watch()
{
	self endon("disconnect");

	for(;;)
	{
		self waittill("weapon_fired");
		kickBack = RandomfloatRange(level.kickbackmin, level.kickbackmax);
		kickSide = RandomfloatRange(level.kicksidemin, level.kicksidemax);
		kickdown = RandomfloatRange(level.kicksidemin, level.kicksidemax);
		kickback = kickback*-1;
		kickdown = (kickdown/2)*-1;
		if(randomint(2))
			kickside = kickside*-1;
		if(self adsButtonPressed())
		{
			kickback = kickback/3;
			kickside = kickside/3;
			kickdown = kickdown/3;
		}
		else
		{
			self SetClientDvar("cg_gun_rot_p", kickback*-12);
			self SetClientDvar("cg_gun_rot_r", kickside*-12);
			self SetClientDvar("cg_gun_rot_y", kickside*12);
		}
		self SetClientDvar("cg_gun_x", kickBack);
		self SetClientDvar("cg_gun_y", kickside);
		self SetClientDvar("cg_gun_z", kickdown);
		wait 0.1;
		self SetClientDvar("cg_gun_x", 0);
		self SetClientDvar("cg_gun_y", 0);
		self SetClientDvar("cg_gun_z", 0);
		self SetClientDvar("cg_gun_rot_p", 0);
		self SetClientDvar("cg_gun_rot_r", 0);
		self SetClientDvar("cg_gun_rot_y", 0);
	}
}

after added save the file into your mods folder and call it whatever you want.

now in _zombiemode.gsc add: (make sure to add the name of the file in the spot specified)

Code Snippet

Plaintext

maps\name_of_file::init

under:

Code Snippet

Plaintext

flag_wait("all_players_connected");

check the script file in your iwd check list and build the iwd

Double Post Merge: April 02, 2016, 01:17:40 am

note that in co-op this may lag a little, i may convert this to be in CSC later to eliminate that but not sure.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has shown excellence and experience in the area of custom mapping in the UGX-Mods community.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

Better Kick and Walking