Custom easter egg messes up on Co-op in Scripting

Created on: April 10, 2016, 04:04:50 pm

Dust
Donator ♥
2,148 Posts
350 Respect +1

For some reason, one of the steps of my easter egg does not work in co-op but it works fine in solo.

This step involves hitting buttons in a certain order. Basically what it does in co-op is, when someone hits a button it acts like you activated it twice.

It comes up "Button is incorrect", or "button is correct" 2 times, thought that was just a print bug, but then when I go to activate the second button it says its incorrect, when it isnt.

It works just fine on solo. When I activate a button, it says it is incorrect or correct one time, and I can continue on from there.

I have no idea what is wrong with it

Code Snippet

Plaintext

activate_buttons()
{
button_easter_egg = getentarray("button_easter_egg","targetname");
array_thread (button_easter_egg,::button_easter_egg);
}

button_easter_egg()
{
self endon("button_easter_egg_complete");

self SetCursorHint("HINT_NOICON");
	while(1)
	{
	self waittill("trigger");
	self thread check_for_correct_button();
	}
}

check_for_correct_button()
{
self endon("button_hit");
		if(isdefined(self.script_noteworthy))
		{
			if(level.number_correct == 1)
			{
				if(self.script_noteworthy == level.number1)
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is correct");
				level.number_correct ++;
				}
				else
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
				level.number_correct = 1;
				}
			self notify("button_hit");
			}
 
			if(level.number_correct == 2)
			{
				if(self.script_noteworthy == level.number2)
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is correct");
				level.number_correct ++;
				}
				else
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
				level.number_correct = 1;
				}
			self notify("button_hit");
			}
 
			if(level.number_correct == 3)
			{	
				if(self.script_noteworthy == level.number3)
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is correct");
				level.number_correct ++;
				}
				else
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
				level.number_correct = 1;
				}
			self notify("button_hit");
			}
 
			if(level.number_correct == 4)
			{	
				if(self.script_noteworthy == level.number4)
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is correct");
				level.number_correct ++;
				}
				else
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
				level.number_correct = 1;
				}
			self notify("button_hit");
			}
			if(level.number_correct == 5)
			{
				if(self.script_noteworthy == level.number5)
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is correct");
				wait 1;
				iprintlnbold("All numbers correct");
				self notify("button_easter_egg_complete");
				button = getentarray("button_easter_egg","targetname");
				for(i=0;i<button.size;i++)
				{
				wait .05;
				button[i] delete();
				}
				thread elemental_easter_egg();
				}
				else
				{
				iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
				level.number_correct = 1;
				}
			self notify("button_hit");
			}
		}
		else
		{
		iprintlnbold("Script Noteworthy not defined");
		}
}

Reply #1 on: April 10, 2016, 04:26:57 pm

This shouldn't be happening. ???
Try printing the level.number_correct after self endon("button_hit"); to see if the function is being called twice and then add some different prints inside the if's.
Also, I wouldn't thread the check_for_correct_button(); function and I'm pretty sure you can simplify it to do just one check for all the numbers. Maybe having the function like this causes problems and if you simplify it, it will work. Don't know.

Marked as best answer by thezombiekilla6 9 years ago

Reply #2 on: April 10, 2016, 05:07:32 pm

daedra descent
Community Daedra
2,789 Posts
238 Respect +1

Quote from: Soy-Yo on April 10, 2016, 04:26:57 pm

Also, I wouldn't thread the check_for_correct_button(); function and I'm pretty sure you can simplify it to do just one check for all the numbers. Maybe having the function like this causes problems and if you simplify it, it will work. Don't know.

Yeah, it shouldn't be threaded. Really an array should be used here as the logic is the same up until the last trigger:

Code Snippet

Plaintext

activate_buttons()
{
	button_easter_egg = getentarray("button_easter_egg","targetname");
	level.switch_order = [];
	level.switch_order[0] = level.number1;
	level.switch_order[1] = level.number2;
	level.switch_order[2] = level.number3;
	level.switch_order[3] = level.number4;
	level.switch_order[4] = level.number5;
	array_thread (button_easter_egg,::button_easter_egg);
}

button_easter_egg()
{
	if(!isDefined(self))
		assertMsg("Self is not defined!");

	if(!isDefined(self.script_noteworthy))
		assertMsg("Script noteworthy not defined for trigger at origin: " + self.origin + "!");

	self endon("button_easter_egg_complete");

	self SetCursorHint("HINT_NOICON");
	while(1)
	{
		self waittill("trigger");
		self check_for_correct_button();
	}
}

check_for_correct_button()
{
	for(i=0;i<level.switch_order.size;i++)
	{
		if(self.script_noteworthy == level.switch_order[i])
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is correct");
			level.number_correct ++;

			if(level.number_correct == 5)
			{
				wait 1;
				iprintlnbold("All numbers correct");
				self notify("button_easter_egg_complete");
				button = getEntArray("button_easter_egg","targetname");
				for(i=0;i<button.size;i++)
				{
					wait .05;
					button[i] delete();
				}
				thread elemental_easter_egg();
			}
		}
		else
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
			level.number_correct = 1;
		}
	}
}

Just easier to look at.

Last Edit: April 10, 2016, 05:07:57 pm by daedra descent

Reply #3 on: April 10, 2016, 05:15:10 pm

Quote from: daedra descent on April 10, 2016, 05:07:32 pm

Code Snippet

Plaintext


		if(self.script_noteworthy == level.switch_order[i])
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is correct");
			level.number_correct ++;

			if(level.number_correct == 5)
			{
}

I think it should be:

Code Snippet

Plaintext

if(level.number_correct == 6)

because you've just summed 1 to level.number_correct. But apart from it, daedra's script seems easier and won't cause you much problems.

Reply #4 on: April 10, 2016, 05:18:15 pm

daedra descent
Community Daedra
2,789 Posts
238 Respect +1

Quote from: Soy-Yo on April 10, 2016, 05:15:10 pm

I think it should be:
Code Snippet
Plaintext
if(level.number_correct == 6)
because you've just summed 1 to level.number_correct. But apart from it, daedra's script seems easier and won't cause you much problems.

Yeah, since the default number correct is 1, it should be 6. My bad.

Reply #5 on: April 10, 2016, 05:42:23 pm

Dust
Donator ♥
2,148 Posts
350 Respect +1

Quote from: daedra descent on April 10, 2016, 05:07:32 pm

Yeah, it shouldn't be threaded. Really an array should be used here as the logic is the same up until the last trigger:

Code Snippet

Plaintext

activate_buttons()
{
	button_easter_egg = getentarray("button_easter_egg","targetname");
	level.switch_order = [];
	level.switch_order[0] = level.number1;
	level.switch_order[1] = level.number2;
	level.switch_order[2] = level.number3;
	level.switch_order[3] = level.number4;
	level.switch_order[4] = level.number5;
	array_thread (button_easter_egg,::button_easter_egg);
}

button_easter_egg()
{
	if(!isDefined(self))
		assertMsg("Self is not defined!");

	if(!isDefined(self.script_noteworthy))
		assertMsg("Script noteworthy not defined for trigger at origin: " + self.origin + "!");

	self endon("button_easter_egg_complete");

	self SetCursorHint("HINT_NOICON");
	while(1)
	{
		self waittill("trigger");
		self check_for_correct_button();
	}
}

check_for_correct_button()
{
	for(i=0;i<level.switch_order.size;i++)
	{
		if(self.script_noteworthy == level.switch_order[i])
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is correct");
			level.number_correct ++;

			if(level.number_correct == 5)
			{
				wait 1;
				iprintlnbold("All numbers correct");
				self notify("button_easter_egg_complete");
				button = getEntArray("button_easter_egg","targetname");
				for(i=0;i<button.size;i++)
				{
					wait .05;
					button[i] delete();
				}
				thread elemental_easter_egg();
			}
		}
		else
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
			level.number_correct = 1;
		}
	}
}

Just easier to look at.

Will try this in a minute and see what happens.

Also what is the difference between threading and not threading? and how can you tell when to thread a function and when not to thread a function.

Just tried it on Solo, and its doing the same thing it was doing on co-op. Activating the button twice instead of only once

Last Edit: April 10, 2016, 05:47:31 pm by thezombiekilla6

Reply #6 on: April 10, 2016, 05:57:04 pm

Quote from: thezombiekilla6 on April 10, 2016, 05:42:23 pm

Also what is the difference between threading and not threading? and how can you tell when to thread a function and when not to thread a function.

If you thread you call the function but the code continues. If you don't thread it, the code will stop there until the function ends or return something. So for example:

Code Snippet

Plaintext

func1() {
    level.var = 5;
    thread func2();
    iprintlnbold( level.var ); // will print 5
}
func1() {
    level.var = 5;
    func2();
    iprintlnbold( level.var ); // will print 10
}

func2() {
    wait .5;
    level.var = 10;
}

I think it's better not to thread unless you want something to run at the same time, like call the same function on multiple ents at the same time or when you want a function to be active during some time with a while loop (play a sound every x seconds or something), for example.

Reply #7 on: April 10, 2016, 06:15:40 pm

daedra descent
Community Daedra
2,789 Posts
238 Respect +1

Quote from: thezombiekilla6 on April 10, 2016, 05:42:23 pm

Also what is the difference between threading and not threading? and how can you tell when to thread a function and when not to thread a function.

Not sure what the big fancy definition is for it, but its basically a new independent thought process. Any function called without threading must be complete before the parent function can continue whatever it was doing. If you thread a function, the parent function can continue to do whatever it would normally had to wait for if it wasn't threaded.

Kinda hard to explain in words. Basically this:

Code Snippet

Plaintext

parent_function()
{
	function_one();
 
	// function two and three won't run until function one is complete.

	function_two();
	function_three();
}
function_one()
{
	while(<something>)
	{
		// code
	}
}
function_two()
{
	// code
}
function_three()
{
	// code
}

Code Snippet

Plaintext

parent_function()
{
	thread function_one();
 
	// function one is threaded. Function and two will now run(assuming function two doesn't have any loops in it or calls anything with loops)

	function_two();
	function_three();
}
function_one()
{
	while(<something>)
	{
		// code
	}
}
function_two()
{
	// code
}
function_three()
{
	// code
}

You would never do this if you needed a function to return a value as the parent function needs whatever the child function returns. Returning a threaded function IS NOT the same as returning on a non threaded function. Returning on a threaded function will just kill the function. You also should never thread anything pre _load as there is an extremely small delay when threading each function.

Quote

Just tried it on Solo, and its doing the same thing it was doing on co-op. Activating the button twice instead of only once

I don't see how that's possible unless your hitting the use button twice. What happens if you print the current trigger, like this:

Code Snippet

Plaintext

activate_buttons()
{
	button_easter_egg = getentarray("button_easter_egg","targetname");
	level.switch_order = [];
	level.switch_order[0] = level.number1;
	level.switch_order[1] = level.number2;
	level.switch_order[2] = level.number3;
	level.switch_order[3] = level.number4;
	level.switch_order[4] = level.number5;
	array_thread (button_easter_egg,::button_easter_egg);
}

button_easter_egg()
{
	if(!isDefined(self))
		assertMsg("Self is not defined!");

	if(!isDefined(self.script_noteworthy))
		assertMsg("Script noteworthy not defined for trigger at origin: " + self.origin + "!");

	self endon("button_easter_egg_complete");

	self SetCursorHint("HINT_NOICON");
	while(1)
	{
		self waittill("trigger");
		self check_for_correct_button();
	}
}

check_for_correct_button()
{
	for(i=0;i<level.switch_order.size;i++)
	{
		if(self.script_noteworthy == level.switch_order[i])
		{
                        iprintln(level.switch_order[i]);
			iprintlnbold("Button " +self.script_noteworthy+ " is correct");
			level.number_correct ++;

			if(level.number_correct == 5)
			{
				wait 1;
				iprintlnbold("All numbers correct");
				self notify("button_easter_egg_complete");
				button = getEntArray("button_easter_egg","targetname");
				for(i=0;i<button.size;i++)
				{
					wait .05;
					button[i] delete();
				}
				thread elemental_easter_egg();
			}
		}
		else
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
			level.number_correct = 1;
		}
	}
}

? What is level.number<number>?

Last Edit: April 10, 2016, 06:16:56 pm by daedra descent

Reply #8 on: April 10, 2016, 07:03:16 pm

Dust
Donator ♥
2,148 Posts
350 Respect +1

Quote from: daedra descent on April 10, 2016, 06:15:40 pm

I don't see how that's possible unless your hitting the use button twice. What happens if you print the current trigger, like this:

Code Snippet

Plaintext

activate_buttons()
{
	button_easter_egg = getentarray("button_easter_egg","targetname");
	level.switch_order = [];
	level.switch_order[0] = level.number1;
	level.switch_order[1] = level.number2;
	level.switch_order[2] = level.number3;
	level.switch_order[3] = level.number4;
	level.switch_order[4] = level.number5;
	array_thread (button_easter_egg,::button_easter_egg);
}

button_easter_egg()
{
	if(!isDefined(self))
		assertMsg("Self is not defined!");

	if(!isDefined(self.script_noteworthy))
		assertMsg("Script noteworthy not defined for trigger at origin: " + self.origin + "!");

	self endon("button_easter_egg_complete");

	self SetCursorHint("HINT_NOICON");
	while(1)
	{
		self waittill("trigger");
		self check_for_correct_button();
	}
}

check_for_correct_button()
{
	for(i=0;i<level.switch_order.size;i++)
	{
		if(self.script_noteworthy == level.switch_order[i])
		{
                        iprintln(level.switch_order[i]);
			iprintlnbold("Button " +self.script_noteworthy+ " is correct");
			level.number_correct ++;

			if(level.number_correct == 5)
			{
				wait 1;
				iprintlnbold("All numbers correct");
				self notify("button_easter_egg_complete");
				button = getEntArray("button_easter_egg","targetname");
				for(i=0;i<button.size;i++)
				{
					wait .05;
					button[i] delete();
				}
				thread elemental_easter_egg();
			}
		}
		else
		{
			iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
			level.number_correct = 1;
		}
	}
}

? What is level.number<number>?

I am only hitting the use button once, and when I add that println line. It prints whatever the script_noteworthy is on the trigger. ie. If I hit button 5, it prints 5, 6 prints 6. so on and so on.

I also dont know if this will work, since they need to hit it in a specific order, that changes every game. Not completely random though, there is 5 different sets of numbers that it could be.

Because with this, no matter what order they hit it in it will still come up Correct.

Like if the order is 5 3 1 4 8. If they try and hit 4 as the first number, it will still say it is correct, when it should be 5.

Reply #9 on: April 10, 2016, 11:09:46 pm

MakeCents
Community Scripter
1,895 Posts
841 Respect +1

I skimmed the comments and I apologize if any of this was mentioned, but I didn't notice it.

What is activate_buttons() thread or called on or from? If it were thread on each player you may see it print twice for 2 player, and 3 for three player. It would just be called though in mapname.gsc, or somewhere, and not done on each player, but I wanted to make sure.

Also ,after your waittill trigger (which would do it on single player too if it were the issue), you don't have a wait that stops it from spamming. I would recommend at least this:

Code Snippet

Plaintext

button_easter_egg()
{
self endon("button_easter_egg_complete");

self SetCursorHint("HINT_NOICON");
	while(1)
	{
	self waittill("trigger",player);
	while(player UseButtonPressed()) wait(.1);//added to wait until they stop pressing used button
	self thread check_for_correct_button();
	}
}

I would agree that using level.number1 and so on is much more difficult to maintain and use than an array but see that you are trying to do something specific so I would still work with an array after that then, like suggested. Assuming you assign the level.number1, and so on, somewhere else before this script runs, I would recommend daedras modifications but with maybe something like this: (modified check_for_correct_button and new function to delete trigs)

Code Snippet

Plaintext


activate_buttons()
{
	button_easter_egg = getentarray("button_easter_egg","targetname");
	level.number_correct = 0;
	level.switch_order = [];
	level.switch_order[0] = level.number1;
	level.switch_order[1] = level.number2;
	level.switch_order[2] = level.number3;
	level.switch_order[3] = level.number4;
	level.switch_order[4] = level.number5;
	array_thread (button_easter_egg,::button_easter_egg);
}
DeleteWhenDone(){
	level waittill("button_easter_egg_complete");
	self delete();
}
button_easter_egg()
{
	if(!isDefined(self))
		assertMsg("Self is not defined!");

	if(!isDefined(self.script_noteworthy))
		assertMsg("Script noteworthy not defined for trigger at origin: " + self.origin + "!");

	self thread DeleteWhenDone();
	level endon("button_easter_egg_complete");

	self SetCursorHint("HINT_NOICON");
	while(1)
	{
	self waittill("trigger",player);
	while(player UseButtonPressed()) wait(.1);
	self thread check_for_correct_button();
	}
}

check_for_correct_button()
{
	if(int(self.script_noteworthy) == int(level.switch_order[level.number_correct])){
		iprintlnbold("Button " +self.script_noteworthy+ " is correct");
		level.number_correct ++;
	}else{
		iprintlnbold("Button " +self.script_noteworthy+ " is incorrect");
		level.number_correct = 0;//edit, fixed 
	}

	if(level.number_correct>=level.switch_order.size){
		iprintlnbold("All numbers correct");
		level notify("button_easter_egg_complete");
	}
}

Edit, fixed the one line and player mistake

Last Edit: April 10, 2016, 11:46:56 pm by MakeCents

Reply #10 on: April 10, 2016, 11:47:30 pm

Dust
Donator ♥
2,148 Posts
350 Respect +1

Well good news, it works on solo again. Will try it on coop later and see how it does, and will let you know what happens

Edit: Nope, it is still activating the buttons twice on coop

Last Edit: April 11, 2016, 12:19:58 am by thezombiekilla6

Reply #11 on: April 11, 2016, 02:59:10 pm

MakeCents
Community Scripter
1,895 Posts
841 Respect +1

Quote from: thezombiekilla6 on April 10, 2016, 11:47:30 pm

Well good news, it works on solo again. Will try it on coop later and see how it does, and will let you know what happens

Edit: Nope, it is still activating the buttons twice on coop

Quote from: MakeCents on April 10, 2016, 11:09:46 pm

What is activate_buttons() thread or called on or from?

It sounds like where ever the function is called from is being called per player. Does it do it three times if there are three players?

Reply #12 on: April 11, 2016, 03:29:36 pm

Dust
Donator ♥
2,148 Posts
350 Respect +1

Quote from: MakeCents on April 11, 2016, 02:59:10 pm

It sounds like where ever the function is called from is being called per player. Does it do it three times if there are three players?

Its being called on the level.

Code Snippet

Plaintext

level thread activate_buttons();

Reply #13 on: April 11, 2016, 03:30:53 pm

MakeCents
Community Scripter
1,895 Posts
841 Respect +1

Quote from: thezombiekilla6 on April 11, 2016, 03:29:36 pm

Its being called on the level.
Code Snippet
Plaintext
level thread activate_buttons();

I assume in mapname.gsc or zombiemode? Not in a loop or anything called on each player or anything like that? Does it do it 3 times for 3 player?

Last Edit: April 11, 2016, 03:33:21 pm by MakeCents

Reply #14 on: April 11, 2016, 03:34:45 pm

Dust
Donator ♥
2,148 Posts
350 Respect +1

Quote from: MakeCents on April 11, 2016, 03:30:53 pm

I assume in mapname.gsc or zombiemode? Not in a loop or anything called on each player or anything like that? Does it do it 3 times for 3 player?

Not sure if it does it 3 times for 3 player, cant test it at the moment.

and in mapname, its just a normal thread.

Code Snippet

Plaintext

thread maps\easter_egg::init();

	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community which have been added to the UGX Map Manager.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

UGX-Mods Login

Custom easter egg messes up on Co-op