Zombie Boss: UberCommando Zombie (Level: Easy) in Scripting

________________________________________________

1. Copy the following files from raw/maps folder into your mod:
_zombiemode
_zombiemode_spawner
(If you already have those files you don't need to copy them)

________________________________________________

2. Copy generic_human.atr, from raw/animtrees to your mod folder. MODNAME/animtrees
add the following things somewhere in that file:
ai_zombie_sprint_w_object_4
ai_zombie_sprint_w_object_5

3. In your mod make a new script file (MODNAME/maps) and paste the following code in there:

Code Snippet

Plaintext

#include maps\_utility; 
#include common_scripts\utility;
#include maps\_zombiemode_utility;

#using_animtree( "generic_human" ); 
spawn_ubercommandozombie()
{
    self endon ("death");

    // Settings
    self.maxhealth = int(level.zombie_health * 3.0);     
    self.health = self.maxhealth;
    range = 300;
    speed_limit = 2.0;
    increasement = 0.05;
    enable_speeding = true;
        
    self.gib_override = false; 
    self.gibbed = true;
    self.ubercommando = true;
    
    self setModel("char_ger_ansel_body");
    
    self.hatModel = "char_ger_waffen_officercap1";
    self attach(self.hatModel);
    
    if (randomInt(100) <= 50)
    {
        self.hatModel2 = "char_ger_honorgd_headgear1";
        self attach(self.hatModel2);
    }
    
    max_speed = 1 + (level.round_number * increasement);
    
    while(1)
    {
        wait randomintrange(10, 30);
        if (!self.ignoreall && self.has_legs)
        {
            self playsound("taunt_vocals_eleven");
            
            anime = random(level._zombie_board_taunt["zombie"]);
            self animscripted("zombie_taunt", self.origin, self.angles, anime);
            wait(getanimlength(anime));
            
            zombies = GetAiSpeciesArray( "axis", "all" );
            for(k = 0; k < zombies.size; k++)
            {
                if (distance( self.origin, zombies[k].origin ) < range && !isdefined(zombies[k].ubercommando))
                {
                    zombies[k] thread speedup_zombies(max_speed, speed_limit, enable_speeding, increasement);
                }
            }
            
            self.run_combatanim = %ai_zombie_sprint_w_object_5;
        }
    }
}

speedup_zombies(max_speed, speed_limit, enable_speeding, increasement)
{    
    self.run_combatanim = %ai_zombie_sprint_w_object_4;
    
    if (!enable_speeding || isdefined(self.ubercommanded))
    {
        return;
    }
    
    self.ubercommanded = true;
    
    rate = self.moveplaybackrate;

    while (rate < max_speed && rate < speed_limit)
    {
        rate += increasement;
        self.melee_anim_rate        = rate;
        self.moveplaybackrate         = rate;
        self.animplaybackrate         = rate;
        self.traverseplaybackrate     = rate;
        wait 1;
    }
    
    rate = speed_limit;
}

(You can for example copy the _zombiemode.gsc file, clear that file and paste this in)
4. openup _zombiemode and look for:

Code Snippet

Plaintext

precache_models()
{
    precachemodel( "char_ger_honorgd_zomb_behead" ); 
    precachemodel( "char_ger_zombieeye" ); 
    PrecacheModel( "tag_origin" ); 
}

change it to this:

Code Snippet

Plaintext

precache_models()
{
    precachemodel( "char_ger_honorgd_zomb_behead" ); 
    precachemodel( "char_ger_zombieeye" ); 
    PrecacheModel( "tag_origin" );

    precachemodel( "char_ger_waffen_officercap1" ); 
    precachemodel( "char_ger_honorgd_headgear1" ); 
    precachemodel( "char_ger_ansel_body" );
}

________________________________________________
5. openup _zombiemode_spawner and look for:

Code Snippet

Plaintext

self notify( "zombie_init_done" );

change it to this:

Code Snippet

Plaintext

self notify( "zombie_init_done" );

if (self.animname != "quad_zombie" && self.animname != "boss_zombie" && self.animname != "zombie_dog")
{
    spawn_round = 5; // the starting round the UberCommando zombie will spawn
    spawn_percentage = 10; // the spawn percentage the UberCommando zombie will spawn

    if (level.round_number >= spawn_round && randomInt(100) <= spawn_percentage)
    {
        self thread maps\YOURSCRIPT::spawn_ubercommandozombie();
    }
}

________________________________________________
6. Add this to your modbuilder:

Code Snippet

Plaintext

// UberCommando zombie
xmodel,char_ger_waffen_officercap1
xmodel,char_ger_honorgd_headgear1
xmodel,char_ger_ansel_body
xanim,ai_zombie_sprint_w_object_4
xanim,ai_zombie_sprint_w_object_5
// UberCommando zombie

________________________________________________
7. Build mod and you're done! Have fun!

UGX-Mods Login

Zombie Boss: UberCommando Zombie (Level: Easy)