[Tutorial] Moon style doors ( open and close when you walk through ) in Scripting

mega.co.nz

Looks like this: ( Note: only works on zombie_door's that have a script_vector! )

http://www.youtube.com/watch?v=V1dnRCfBf8A#ws

Radiant:
Keep your normal door-triggers for the first time use, with al their normal KVP's.
For the moon-doors add a trigger_multiple, when a zombie / player is touching that, the doors will open.
Trigger KVP's:

Code Snippet

Plaintext

-Select Spawnflag:  AI_AXIS

targetname		-		auto_door_trig				( the same for all door_triggers in your map )
script_noteworthy	-		auto_door#				( give each door a unique nr )
script_flag		-		** 					( copy from the normal door trigger it 'belongs to' )

make the trigger target every part of the door ( also clips! ). So first select trigger, then door/clip and press 'w' for each part.

Call the script from _zombiemode.gsc, around line 60-70 you'll see similar line's: add this line:

maps\_blst_auto_doors::auto_doors_init();

There are 3 spots in the script to put in sounds, right now they are empty but i left note's where you need to add them in the script.

Download the script, or copy it from the code-box and put it in a new .gsc named _blst_auto_doors.gsc Place that .gsc in your root\mods\mapname\maps\ folder..

Code Snippet

Plaintext

#include maps\_utility; 
#include common_scripts\utility;
#include maps\_zombiemode_utility;

auto_doors_init()
{
	triggers = getentarray( "auto_door_trig", "targetname" );
	array_thread( triggers,::auto_doors_wait );
	array_thread( triggers,::auto_doors );
}

auto_doors_wait()
{
	wait 1;
	self.active = false;
	flag_wait( self.script_flag );
	wait 3;
	self.active = true;
}

auto_doors()
{
	wait 1.5;	
 
	doors = getentarray( self.target, "targetname" );
	for( i=0;i<doors.size;i++ )
	{
		doors[i].open = doors[i].origin+doors[i].script_vector;
		doors[i].closed = doors[i].origin;
	}
 
	self.target = undefined;
	self.state = "closed";
 
	while( !self.active )
		wait 0.5;
 
	self close_doors( doors );
 
	while(1)
	{
		self waittill( "trigger" );									
		playsoundatposition( "", doors[0].origin );											// ADD SOUNDS HERE, when the trigger activate's
 
		switch( self.state )
		{
			case "closed":
			self open_doors( doors );
			wait 3;
			self close_doors( doors );
			break;
 
			case "open":
			self close_doors( doors );
			break;
 
			default:
			break;
		}
	}
}
 
open_doors( doors )
{
	self.state = "open";
	for(i=0;i<doors.size;i++ )
	{
		doors[i] moveto( doors[i].open, 1, 0.3, 0.3 );
	}
	playsoundatposition( "", doors[0].origin );												// ADD SOUNDS HERE, opening of the doors
	wait 1.5;
}	
 

close_doors( doors )							
{
	while(1)
	{
		count = 0;
 
		for(i=0;i<get_players().size;i++ )
		{
			if( get_players()[i] istouching( self ) )
			{
				count++;
				break;
			}
		}
 
		if( count == 0 )
		{
			zombs = getaiarray( "axis");
			for(i=0;i<zombs.size;i++ )
			{
				if( zombs[i] istouching( self ) )
				{
					count++;
					break;
				}
			}
		}

		if( count >= 1 )
		{
			wait 0.5;
			continue;
		}
 
 
		self thread move_doors_closed( doors );
		self.state = "closed";
		break;
	}
}
 
move_doors_closed( doors )
{	
	for(i=0;i<doors.size;i++ )
	{
		doors[i] moveto( doors[i].closed, 1, 0.3, 0.3 );
	}
	playsoundatposition( "", doors[0].origin );												// ADD SOUNDS HERE, closing of the doors
}

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
UGX V.I.P.
	Has released one or more maps to the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
Oil Rig Beta Access

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

[Tutorial] Moon style doors ( open and close when you walk through )