https://ugx-mods.com/forum/index.php?topic=8491.msg153519#msg153519 YOu know how to do this but not with points I need how to do this tutorial with zombies souls you understund??? pls help me

souls zombies in Scripting

Make a trigger_multiple or trigger_radius in radiant, players need to kill zombies inside this trigger. Give it this KVP: "soul_trig" - "targetname"

Then make a door using a script_(brush)model(s),
-give it a targetname: "soul_door" - "targetname"
-use a script_vector to tell it where to move to
-make sure it's DYNAMICPATH spawnflag is ticked
-if it needs to activate a zone add the script_flag ( if you use multiple models/brushes for the door, just give one of them the script_flag KVP )

create a script_struct where the fx for the souls need to fly towards: "soul_fx_pos", "targetname"

Then in your _zombiemode.gsc you'll see lines around line 60 - 70 that look like this:

Code Snippet

Plaintext

 	maps\_zombiemode_dogs::init();

Add this to the list:

Code Snippet

Plaintext

 soul_tracker_init();

And at the bottom of the file add this,
This door needs 25 kills to open ( self.souls == 25 ), you can your add FX for the souls and a sound to the script.
script untested might have a typo here and there

Code Snippet

Plaintext

soul_tracker_init()
{
	soul_door = getentarray( "soul_door", "targetname" );

	for( i=0 ; i<soul_door.size ; i++ )
	{
		if( isDefined(soul_door[i].script_flag) && !IsDefined( level.flag[soul_door[i].script_flag] ) ) 
			flag_init( soul_door[i].script_flag ); 
	}
 
	level thread zombie_soul_start();
}
zombie_soul_start()
{
	trig = getent( "soul_trig", "targetname" );

	while(isdefined(trig))
	{
		zombies = getaiarray( "axis" );
		for( i=0 ; i<zombies.size ; i++ )
		{
			if( !isdefined( zombies[i].soul_zombie ) )
			{
				zombies[i].soul_zombie = true;
				zombies[i] thread soul_watch( trig );
			}
		}
 
		wait 0.5;
	}
}
soul_watch(trig)
{
	self waittill( "death", attacker );
 
	if( !isdefined( trig ) )
		return;
 
	if( isdefined(attacker) && !isplayer( attacker ) )
		return;
 
	if( self istouching( trig ) )
		trig thread add_soul_to_door(self.origin);
}
add_soul_to_door(death_origin)
{
	if( !isdefined( self.souls ) )
		self.souls = 0;
 
	self.souls++;
	fx_pos = getstruct( "soul_fx_pos", "targetname" );
	fx_tag = spawn( "script_model", death_origin+(0,0,30) );
	fx_tag setmodel( "tag_origin" );
	playfxontag( level._effect[ "YOUR_SOUL_FX" ], fx_tag, "tag_origin" );				// SOUL FX
	fx_tag moveto( fx_pos.origin, 2, 1, 0 );
	wait 2;
	fx_tag delete();
	playsoundatposition( "SOUL_ADDING_SOUND", fx_pos.origin );						// SOUND WHEN A SOUL GETS ADDED
 
	if( self.souls == 25 )
	{
		level thread open_special_door();
		self delete();
	}
}
open_special_door()
{
	soul_door = getentarray( "soul_door", "targetname" );
 
	for( i=0 ; i<soul_door.size ; i++ )
	{
		soul_door[i] notsolid();
		soul_door[i] connectpaths();
		soul_door[i] moveto( (soul_door[i].origin+soul_door[i].script_vector), 2, 0.5, 0.5 );
 
		if( isdefined( soul_door[i].script_flag ) )
			flag_set( soul_door[i].script_flag );
	}
}

playfxontag( level._effect[ YOUR_SOUL_FX ], fx_tag, "tag_origin" ); // SOUL FX playsoundatposition( SOUL_ADDING_SOUND, fx_pos.origin ); // SOUND WHEN A SOUL GETS ADDED

self.souls++; fx_pos = getstruct( "soul_fx_pos", "targetname" ); fx_tag = spawn( "script_model", death_origin+(0,0,30) ); fx_tag setmodel( "tag_origin" ); //playfxontag( level._effect[ YOUR_SOUL_FX ], fx_tag, "tag_origin" ); // SOUL FX fxtag moveto( fx_pos.origin, 2, 1, 0 ); wait 2; fxtag delete(); //playsoundatposition( SOUL_ADDING_SOUND, fx_pos.origin ); // SOUND WHEN A SOUL GETS ADDED

self.souls++; fx_pos = getstruct( "soul_fx_pos", "targetname" ); //fx_tag = spawn( "script_model", death_origin+(0,0,30) ); //fx_tag setmodel( "tag_origin" ); //playfxontag( level._effect[ YOUR_SOUL_FX ], fx_tag, "tag_origin" ); // SOUL FX //fxtag moveto( fx_pos.origin, 2, 1, 0 ); wait 2; //fxtag delete(); //playsoundatposition( SOUL_ADDING_SOUND, fx_pos.origin ); // SOUND WHEN A SOUL GETS ADDED

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
Oil Rig Beta Access

UGX-Mods Login

souls zombies