I'm thinking in a new map, but before I begin making it I need to know if it's possible. I know how to move brushes, triggers..., but is there any way to move prefabs without stamping them? Thanks.

yes, you would have to move every single piece seperately. Dont think you can move structs, maybe just like triggers you can give them a new .origin, but i dont think moveto() for example will work on a struct. Change it into an _origin and adjust the perk-script to work with that is also an option.

Moving things in Scripting

Quote from: Soy-Yo on September 06, 2015, 07:49:07 pm

Yeah, I knew those. I'm sure they work with triggers, zones and zombies, but do them work with everything?

I'll make a script example and prefabs for you later tonight, with an explanation.

Double Post Merge: September 07, 2015, 06:05:44 am

Well, I regret to inform that this whole time I thought I was moving the struct, and I wasn't,

so blunt was right on the linkto buisness not working for them. Which means I'll have to adjust that in the future for my randomizer. I made something to move the struct the way blunt said in the script.

I made a pefab, explained below, then a script, and then I made a video, which I placed at the bottom to see what it is doing. This script prob won't work for what you are doing, you may need to be more specific, but it shows how you can move one item and everything goes with it. I inserted the prefab and pressed space to copy it three times.

PREFAB
I set up a prefab, with an ent, then linked a trigger, and then linked a struct to the trigger and a couple more ents so you can see it is all linked.

SCRIPT
Then I made a function to get an array of my ents (GetMyParts). Next I thread a function on each ent that gets the target ent and links it to the ent. If that target ent also has a target, then get it and link it too but calling the same function on it, and so on and so on. Then I made a function just to do something to show that it is working. It will play an fx after moving at the struct position. The functions below are to "move" a struct or array of structs. It spawns an ent where the struct is, links to the ent that you will move, and then moves the struct to the ent after it moves, then deletes it.

Code Snippet

Plaintext

//thread GetMyParts();
GetMyParts(){//get all the models to move
	parts = getentarray("exampleparts", "targetname");
	array_thread(parts,::LinkParts);
}
LinkParts(){//decide to link and/or get more ents to link
	if(!isDefined(self.target)) return;
	myEnts = GetEntArray(self.target,"targetname");
	if(isDefined(myEnts) && myEnts.size>0){
		array_thread(myEnts,::LinkParts, self);
		array_thread(myEnts,::LinkThem,self);
	}
}
LinkThem(linkToMe){//enable link for trigs and link everything
	if(isDefined(self.classname) && isSubStr(self.classname,"trigger")){
		self SetCursorHint("HINT_NOICON");//I only do this hear, cause it isn't done else where
		self setHintString("Press &&1 to do something");//I only do this hear, cause it isn't done else where
		self thread MakeMeDoSomething(linkToMe);
		self enableLinkTo();
	}
	self linkto(linkToMe);
}
MakeMeDoSomething(moveMe){//just to move it and test
	if(!isDefined(moveMe)) return;
	while(1){
		self waittill("trigger");
		self MoveMyStructs(moveMe, 200);
		wait(5);
		self MoveMyStructs(moveMe, -200);
	}
}
//Functions that "move" structs
MoveMyStructs(moveMe, move){//struct moving functions
	structs = undefined;
	if(isdefined(self.target)) structs = GetStructArray(self.target,"targetname");
	if(isDefined(structs) && structs.size>0) for(i=0;i<structs.size;i++) moveMe BeforeMoveStructs(structs[i]); 
	moveMe MoveTo(moveMe.origin + (0,0,int(move)),.01);
	wait(.1);
	if(isDefined(structs) && structs.size>0) for(i=0;i<structs.size;i++) moveMe AfterMoveStructs(structs[i]);
}
BeforeMoveStructs(struct){//struct moving functions
	ent = spawn("script_origin",struct.origin);
	ent.origin = struct.origin;
	ent linkto(self);
	struct.ent = ent;
}
AfterMoveStructs(struct){//struct moving functions
	struct.origin = struct.ent.origin;
	struct.ent delete();
	struct.ent = undefined;
	PlayFx(level._effect["poltergeist"], struct.origin);
}

! No longer available

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Has released one or more maps to the UGX-Mods community.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
Oil Rig Beta Access

UGX-Mods Login

Moving things