[BO1] Help Removing Player Priority in Scripting

Created on: December 24, 2015, 04:01:56 am

In BO1, zombies are more attracted towards white player. I was wondering if there was a way to remove this. I've tried and so far haven't found out how. Here is the _zombiemode_spawner script. I think it has something to do with self.favoriteenemy or self.ignore_player

http://pastebin.com/Q92wmwdr

Here is find_flesh(), the function that I believe causes this to happen.

Code Snippet

Plaintext

find_flesh()
{
	self endon( "death" ); 
	level endon( "intermission" );
	self endon( "stop_find_flesh" );
	if( level.intermission )
	{
		return;
	}
 
	self.helitarget = true;
	self.ignoreme = false; 
	self.noDodgeMove = true; 
 
 
	self.ignore_player = [];
	self zombie_history( "find flesh -> start" );
	self.goalradius = 32;
	while( 1 )
	{
 
 
 
		near_zombies = getaiarray("axis");
		same_enemy_count = 0;
		for (i = 0; i < near_zombies.size; i++)
		{
			if ( isdefined( near_zombies[i] ) && isalive( near_zombies[i] ) )
			{
				if ( isdefined( near_zombies[i].favoriteenemy ) && isdefined( self.favoriteenemy ) 
				&&	near_zombies[i].favoriteenemy == self.favoriteenemy )
				{
					if ( distancesquared( near_zombies[i].origin, self.favoriteenemy.origin ) < 225 * 225 
					&&	 distancesquared( near_zombies[i].origin, self.origin ) > 525 * 525)
					{
						same_enemy_count++;
					}
				}
			}
		}
 
		if (same_enemy_count > 12)
		{
			self.ignore_player[self.ignore_player.size] = self.favoriteenemy;
		}
 
 
 
		if (isDefined(level.zombieTheaterTeleporterSeekLogicFunc) )
		{
       		self [[ level.zombieTheaterTeleporterSeekLogicFunc ]]();
       	}
       	
		zombie_poi = self get_zombie_point_of_interest( self.origin );
 
		players = get_players();
 
 
		if( players.size == 1 )
		{
			self.ignore_player = [];
		}
 
		else
		{
			for(i = 0; i < self.ignore_player.size; i++)
			{
				if( IsDefined( self.ignore_player[i] ) && IsDefined( self.ignore_player[i].ignore_counter ) && self.ignore_player[i].ignore_counter > 3 )
				{
					self.ignore_player[i].ignore_counter = 0;
					self.ignore_player = array_remove( self.ignore_player, self.ignore_player[i] );
				}
			}
		}
 
		player = get_closest_valid_player( self.origin, self.ignore_player );
		if( !isDefined( player ) && !isDefined( zombie_poi ) )
		{
			self zombie_history( "find flesh -> can't find player, continue" );
			if( IsDefined( self.ignore_player ) )
			{
				self.ignore_player = [];
			}
			wait( 1 ); 
			continue; 
		}
 
 
 
		//if ( !isDefined( level.check_for_alternate_poi ) || ![[level.check_for_alternate_poi]]() )
		{
			self.enemyoverride = zombie_poi;
			self.favoriteenemy = player;
		}
 
		self thread zombie_pathing();
 
 
		if( players.size > 1 )
		{
			for(i = 0; i < self.ignore_player.size; i++)
			{
				if( IsDefined( self.ignore_player[i] ) )
				{
					if( !IsDefined( self.ignore_player[i].ignore_counter ) )
						self.ignore_player[i].ignore_counter = 0;
					else
						self.ignore_player[i].ignore_counter += 1;
				}
			}
		}
 
		self thread attractors_generated_listener();
		self.zombie_path_timer = GetTime() + ( RandomFloatRange( 1, 3 ) * 1000 );
		while( GetTime() < self.zombie_path_timer ) 
		{
			wait( 0.1 );
		}
		self notify( "path_timer_done" );
		self zombie_history( "find flesh -> bottom of loop" );
		debug_print( "Zombie is re-acquiring enemy, ending breadcrumb search" );
		self notify( "zombie_acquire_enemy" );
	}
}

Last Edit: December 24, 2015, 04:03:59 am by jbird

Reply #1 on: December 24, 2015, 04:05:22 am

i think it is networking related, as the white player is always the host if i am not mistaken

Reply #2 on: December 24, 2015, 04:14:42 am

alaurenc9
Scripter
577 Posts
163 Respect +1

i feel like this is because in every check in an array of players, player 0 ( white ) is always first. if there are checks that just go through who ever passes first, white player will always be checked first so he might always pass first. idk just a thought

Reply #3 on: December 24, 2015, 04:35:34 am

Quote from: vinnyz500 on December 24, 2015, 04:05:22 am

i think it is networking related, as the white player is always the host if i am not mistaken

White player is only always host on PC. On consoles, white player may not be host sometimes and it is still the white player the zombies are most attracted to.

Double Post Merge: December 24, 2015, 04:36:21 am

Quote from: alaurenc9 on December 24, 2015, 04:14:42 am

i feel like this is because in every check in an array of players, player 0 ( white ) is always first. if there are checks that just go through who ever passes first, white player will always be checked first so he might always pass first. idk just a thought

Is there a way I could get the zombies to truly go after which player is closest to them?

Last Edit: December 24, 2015, 04:36:21 am by jbird

Reply #4 on: December 24, 2015, 02:38:21 pm

Harry Bo21
Scripter
6,875 Posts
908 Respect +1

Quote from: vinnyz500 on December 24, 2015, 04:05:22 am

i think it is networking related, as the white player is always the host if i am not mistaken

at a guess, its not the "white" player, its the "first player in the array"

so rearrange the array

Code Snippet

Plaintext

players = get_players();
players = array_randomize( players );

will randomize the order

and it already uses - the closest player

also, for good coding practice ( not really needed here but anyway )

Code Snippet

Plaintext

players = get_players();

if ( !isDefined( players ) || players.size < 1 )
    return; 

players = array_randomize( players );

in this case tho, you would have to decide for yourself if or not to "return"

Last Edit: December 24, 2015, 02:43:13 pm by Harry Bo21

Reply #5 on: December 24, 2015, 05:09:27 pm

The reason is simple... its the for statements. It does player 0 first, then 1 then 2 etc.

Reply #6 on: December 24, 2015, 08:04:21 pm

alaurenc9
Scripter
577 Posts
163 Respect +1

Quote from: liamsa669 on December 24, 2015, 05:09:27 pm

The reason is simple... its the for statements. It does player 0 first, then 1 then 2 etc.

I said this already 3 comments above yours

Reply #7 on: December 25, 2015, 05:23:00 pm

Quote from: alaurenc9 on December 24, 2015, 08:04:21 pm

I said this already 3 comments above yours

that moment when someone assumes u read more than the 1st comment

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

[BO1] Help Removing Player Priority