Is there a way I can make that when a max ammo is picked up, it refills the players clip alongside the reserved ammo?

Refilling Clip/Mag with Max Ammo in Scripting

In _zombiemode_powerups.gsc, look for the function full_ammo_powerup( drop_item ), replace it with this:

Code Snippet

Plaintext

full_ammo_powerup( drop_item )
{
	players = get_players();

	for (i = 0; i < players.size; i++)
	{
		primaryWeapons = players[i] GetWeaponsList(); 

		for( x = 0; x < primaryWeapons.size; x++ )
		{
			players[i] GiveMaxAmmo( primaryWeapons[x] );
			players[i] setWeaponAmmoClip( primaryWeapons[x], weaponClipSize( primaryWeapons[x] ) );
		}
	}
	//	array_thread (players, ::full_ammo_on_hud, drop_item);
	level thread full_ammo_on_hud( drop_item );
}

Quote from: arceus on November 28, 2014, 05:38:24 pm

Code Snippet
Plaintext
refill_mag()
{
	weapon = self getcurrentweapon();

	ammo = WeaponClipSize( "weapon" );

	self SetWeaponAmmoClip( "weapon", ammo );
}
somthing like this although this will work for the weapon the player is holding

Ples... "weapon" is not a variable name but a string, so it should look like this:

Code Snippet

Plaintext

refill_mag()
{
	weapon = self getcurrentweapon();

	ammo = WeaponClipSize( weapon );

	self SetWeaponAmmoClip( weapon, ammo );
}

Tbh, wouldn't store ammo in a variable if you're only going to use it once:

Code Snippet

Plaintext

weap = self getCurrentWeapon();
self setWeaponAmmoClip( weap, weaponClipSize( weap ) );

Quote from: DidUknowiPwn on November 28, 2014, 06:22:24 pm

Pretty sure you could just do giveMaxAmmo("weapon") instead.

Nope, this is the stock max ammo script:

Code Snippet

Plaintext

full_ammo_powerup( drop_item )
{
	players = get_players();

	for (i = 0; i < players.size; i++)
	{
		primaryWeapons = players[i] GetWeaponsList(); 

		for( x = 0; x < primaryWeapons.size; x++ )
		{
			players[i] GiveMaxAmmo( primaryWeapons[x] );
		}
	}
	//	array_thread (players, ::full_ammo_on_hud, drop_item);
	level thread full_ammo_on_hud( drop_item );
}

giveMaxAmmo() only refills the reserve ammo.


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha


	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
BO3 Modtools Alpha	This user has access to the Black Ops 3 Modtools Alpha

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown excellence and experience in the area of custom scripting in the UGX-Mods community.
Oil Rig Beta Access

UGX-Mods Login

Refilling Clip/Mag with Max Ammo