Losing Electric Cherry when Down in Scripting

Created on: April 25, 2014, 08:16:27 pm

2 problems: I don't lose Cherry when I down and I experience extreme lag (almost freezing) when the game starts. Here is my Cherry script. Thanks in advance.

Code Snippet

Plaintext

#include maps\_anim; 
#include maps\_utility; 
#include common_scripts\utility;
#include maps\_music; 
#include maps\_zombiemode_utility; 

main()
{
	flag_wait("all_players_connected");
	wait(1);
	players = get_players();
	for(i = 0; i < players.size; i++)
	{
		players[i] thread cherry_effect();
		players[i] thread cherry_down();
	}
}

cherry_effect()
{  
	while(1)
	{
		self waittill( "reload_start" );
		if( self HasPerk("specialty_boost"))
		{
			cherry_weapon = self GetCurrentWeapon();
			ammo_left = self GetWeaponAmmoClip( cherry_weapon );
			clip_size = WeaponClipSize( cherry_weapon );
			ratio = ammo_left / clip_size;
			damage = 1200 - (ratio * 1200);
			iprintln( damage );
			touching_check = spawn("trigger_radius",self.origin,1,200,200);
			zombies = getaispeciesarray("axis","all");
			for(j = 0; j < zombies.size; j++)
			{
				if(zombies[j] IsTouching( touching_check ))
				{
					zombies[j] maps\_zombiemode_tesla::tesla_play_death_fx( 1 );
					zombies[j] SetFlashBanged( true, 1 );
				}
				else
				{
					continue;
				}
			}
			touching_check delete();
			SetPlayerIgnoreRadiusDamage( true );
			RadiusDamage( self.origin, 200, damage, 50, self );
			wait(5);
		}
		else
		{
		}
	}
}

cherry_down()
{
	while(1)
	{
		if(self HasPerk("specialty_boost"))
		{
			while(1)
			{
				self waittill_any( "fake_death", "death", "player_downed" );
				touching_check = spawn("trigger_radius",self.origin,1,200,200);
				zombies = getaispeciesarray("axis","all");
				for(j = 0; j < zombies.size; j++)
				{
					if(zombies[j] IsTouching( touching_check ))
					{
						zombies[j] maps\_zombiemode_tesla::tesla_play_death_fx( 1 );
						zombies[j] SetFlashBanged( true, 1 );
					}
					else
					{
						continue;
					}
				}
				touching_check delete();
				SetPlayerIgnoreRadiusDamage( true );
				RadiusDamage( self.origin, 150, 1200, 50, self );
				self UnSetPerk("specialty_boost");
				break;
			}
		}
		else
		{
			continue;
		}
	}
}

Reply #1 on: April 25, 2014, 08:25:41 pm

PROxFTW
Scripter
214 Posts
82 Respect +1

For the lag I might be able to help
However for the death check right after self UnsetPerk
Do a notify
Then right above the while(1) in cherry_effect
Do an Endon

Let me know how this works out

As for the lag did it start when you added the script or sometime before?

Marked as best answer by nabaro 12 years ago

Reply #2 on: April 25, 2014, 08:29:43 pm

YaPh1l
Scripter Elite
277 Posts
112 Respect +1

You don't have any wait() in your outermost while loop in cherry_down().

- Phil.

Reply #3 on: April 25, 2014, 08:37:06 pm

2 things: adding the wait didn't help, unless I misinterpreted your statement. Also, I realized that the innermost while loop in cherry_down() was useless, so I removed it. Here is the current script:

Code Snippet

Plaintext

#include maps\_anim; 
#include maps\_utility; 
#include common_scripts\utility;
#include maps\_music; 
#include maps\_zombiemode_utility; 

main()
{
	flag_wait("all_players_connected");
	wait(1);
	players = get_players();
	for(i = 0; i < players.size; i++)
	{
		players[i] thread cherry_effect();
		players[i] thread cherry_down();
	}
}

cherry_effect()
{  
	while(1)
	{
		self waittill( "reload_start" );
		if( self HasPerk("specialty_boost"))
		{
			cherry_weapon = self GetCurrentWeapon();
			ammo_left = self GetWeaponAmmoClip( cherry_weapon );
			clip_size = WeaponClipSize( cherry_weapon );
			ratio = ammo_left / clip_size;
			damage = 1200 - (ratio * 1200);
			iprintln( damage );
			touching_check = spawn("trigger_radius",self.origin,1,200,200);
			zombies = getaispeciesarray("axis","all");
			for(j = 0; j < zombies.size; j++)
			{
				if(zombies[j] IsTouching( touching_check ))
				{
					zombies[j] maps\_zombiemode_tesla::tesla_play_death_fx( 1 );
					zombies[j] SetFlashBanged( true, 1 );
				}
				else
				{
					continue;
				}
			}
			touching_check delete();
			SetPlayerIgnoreRadiusDamage( true );
			RadiusDamage( self.origin, 200, damage, 50, self );
			wait(5);
		}
		else
		{
		}
	}
}

cherry_down()
{
	while(1)
	{
		if(self HasPerk("specialty_boost"))
		{
			self waittill_any( "fake_death", "death", "player_downed" );
			touching_check = spawn("trigger_radius",self.origin,1,200,200);
			zombies = getaispeciesarray("axis","all");
			for(j = 0; j < zombies.size; j++)
			{
				if(zombies[j] IsTouching( touching_check ))
				{
					zombies[j] maps\_zombiemode_tesla::tesla_play_death_fx( 1 );
					zombies[j] SetFlashBanged( true, 1 );
				}
				else
				{
					continue;
				}
			}
			touching_check delete();
			SetPlayerIgnoreRadiusDamage( true );
			RadiusDamage( self.origin, 150, 1200, 50, self );
			self UnSetPerk("specialty_boost");
			wait(5);
		}
		else
		{
			continue;
		}
	}
}

Also, wouldn't using a notify never allow for me to use the effects of cherry after my first down?

Post Merge: April 25, 2014, 08:40:16 pm

One more thing, using developer 1 in game shows that, at the time of the lag, there is a script runtime error: potential infinite loop: killing thread.

Last Edit: April 25, 2014, 08:40:16 pm by nabaro

Reply #4 on: April 25, 2014, 08:40:42 pm

YaPh1l
Scripter Elite
277 Posts
112 Respect +1

You put the wait in the wrong position, you should be waiting in the else clause, because if you don't, the loop will be terminated by the engine when you don't have the perk as it creates an "infinite loop" error.

- Phil.

Reply #5 on: April 25, 2014, 08:42:12 pm

Like this?

Code Snippet

Plaintext

else
{
	wait(0.05);
	continue;
}

Post Merge: April 25, 2014, 08:44:13 pm

Yep, it works perfectly! Thanks Phil!

Last Edit: April 25, 2014, 08:44:13 pm by nabaro

Reply #6 on: April 25, 2014, 08:52:51 pm

YaPh1l
Scripter Elite
277 Posts
112 Respect +1

I don't suppose it is necessary to wait for such a short time only, something a little longer should work too.

- Phil.

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

Losing Electric Cherry when Down