Betty Trigger Help in Scripting

Created on: June 21, 2015, 08:20:57 am

Code Snippet

Plaintext

betty_think()
{
	wait(2);
	trigger = spawn("trigger_radius",self.origin,9,80,64);
	trigger thread player_trigger(); //line that calls the script
	trigger waittill( "trigger" );
	trigger = trigger;
	self playsound("betty_activated");
	wait(.1);	
	fake_model = spawn("script_model",self.origin);
	fake_model setmodel(self.model);
	self hide();
	tag_origin = spawn("script_model",self.origin);
	tag_origin setmodel("tag_origin");
	tag_origin linkto(fake_model);
	playfxontag(level._effect["betty_trail"], tag_origin,"tag_origin");
	fake_model moveto (fake_model.origin + (0,0,32),.2);
	fake_model waittill("movedone");
	playfx(level._effect["betty_explode"], fake_model.origin);
	earthquake(1, .4, fake_model.origin, 512);

	//CHris_P - betties do no damage to the players
	zombs = getaispeciesarray("axis");
	for(i=0;i<zombs.size;i++)
	{
		//PI ESM: added a z check so that it doesn't kill zombies up or down one floor
		if(zombs[i].origin[2] < fake_model.origin[2] + 80 && zombs[i].origin[2] > fake_model.origin[2] - 80 && DistanceSquared(zombs[i].origin, fake_model.origin) < 200 * 200)
		{
			zombs[i] thread maps\_zombiemode_spawner::zombie_damage( "MOD_ZOMBIE_BETTY", "none", zombs[i].origin, self.owner );
		}
	}
	players = get_players();
	for(i=0;i<players.size;i++)
	{
		//iprintln( Distance( players[i].origin , self.origin ) );
		if( players[i].origin[2] < fake_model.origin[2] + 80 && players[i].origin[2] > fake_model.origin[2] - 80 && Distance( players[i].origin , fake_model.origin ) <= 200 && players[i] != self.owner )
		{
			if(players[i].health > 50)
			{
				players[i] DoDamage( 160, self.origin );
			}
			else
			{
				radiusdamage(players[i].origin,10,players[i].health + 100,players[i].health + 100);
			}
		}
	}

	trigger delete();
	fake_model delete();
	tag_origin delete();
	if( isdefined( self ) )
	{
		self delete();
	}
}

Code Snippet

Plaintext

player_trigger() //self = trigger
{
	while(1)
	{
		players = get_players();
		for(i=0;i<players.size;i++)
		{
			if (players[i] isTouching (self) && players[i] != self.owner) //line that needs fixing
			{
				self notify( "trigger" );
				break;
			}
		}
		wait (0.05);
	}
}

I got it so bouncing betties can be activated by players, the only thing I want to fix is that I want the player who placed the betty not to be able activate their own betty. What I have currently doesn't work, any suggestions?

Last Edit: June 21, 2015, 08:21:31 am by jbird

This topic contains a post which is marked as the Best Answer. Click here to view it.

Reply #1 on: June 21, 2015, 09:05:09 am

daedra descent
Community Daedra
2,789 Posts
230 Respect +1

Small rant:

Spoiler: click to open...

Yet another help topic created by you so other people can look through your terrible code and fix your mistakes.

Whatever. That is what the help desk is for, it just rubs me the wrong way when:

A. You haven't credited anyone in your FFA mod on factory or any of your tutorials

B. Your code is god awful.

C. You don't listen to people when they tell you your code is wrong/not the right way to do it.

self.owner isn't defined.

Other issues:
The .origins on AI, players, and entities are NOT arrays and CANNOT have an index.
Setting the variable 'trigger' to itself is pointless and does nothing.

And just gonna leave this here: http://ugx-mods.com/forum/index.php?topic=2891.0

Last Edit: June 21, 2015, 09:06:21 am by daedra descent

Reply #2 on: June 21, 2015, 09:06:32 am

Harry Bo21
Scripter
6,875 Posts
908 Respect +1

youve threaded it on the trigger not the betty so

self.owner

is not checking the betty, its checking the trigger, which is undefined

Quote

Setting the variable 'trigger' to itself is pointless and does nothing.

That one is treyarchs bad, heres the original

Code Snippet

Plaintext

betty_think()
{
	wait(2);
	trigger = spawn("trigger_radius",self.origin,9,80,64);
	trigger waittill( "trigger" );
 
 
	trigger = trigger;
	self playsound("betty_activated");
	wait(.1);	
	fake_model = spawn("script_model",self.origin);
	fake_model setmodel(self.model);
	self hide();
	tag_origin = spawn("script_model",self.origin);
	tag_origin setmodel("tag_origin");
	tag_origin linkto(fake_model);
	playfxontag(level._effect["betty_trail"], tag_origin,"tag_origin");
	fake_model moveto (fake_model.origin + (0,0,32),.2);
	fake_model waittill("movedone");
	playfx(level._effect["betty_explode"], fake_model.origin);
	earthquake(1, .4, fake_model.origin, 512);

	//CHris_P - betties do no damage to the players
	zombs = getaispeciesarray("axis");
	for(i=0;i<zombs.size;i++)
	{
		//PI ESM: added a z check so that it doesn't kill zombies up or down one floor
		if(zombs[i].origin[2] < fake_model.origin[2] + 80 && zombs[i].origin[2] > fake_model.origin[2] - 80 && DistanceSquared(zombs[i].origin, fake_model.origin) < 200 * 200)
		{
			zombs[i] thread maps\_zombiemode_spawner::zombie_damage( "MOD_ZOMBIE_BETTY", "none", zombs[i].origin, self.owner );
		}
	}
	//radiusdamage(self.origin,128,1000,75,self.owner);

	trigger delete();
	fake_model delete();
	tag_origin delete();
	if( isdefined( self ) )
	{
		self delete();
	}
}

Last Edit: June 21, 2015, 09:07:38 am by Harry Bo21

Reply #3 on: June 21, 2015, 09:12:23 am

daedra descent
Community Daedra
2,789 Posts
230 Respect +1

Quote from: Harry Bo21 on June 21, 2015, 09:06:32 am

That one is treyarchs bad, heres the original

I know, i was just pointing out it wasn't necessary.

Reply #4 on: June 21, 2015, 09:20:52 am

Quote from: Harry Bo21 on June 21, 2015, 09:06:32 am

youve threaded it on the trigger not the betty so

self.owner

is not checking the betty, its checking the trigger, which is undefined

That one is treyarchs bad, heres the original

Code Snippet

Plaintext

betty_think()
{
	wait(2);
	trigger = spawn("trigger_radius",self.origin,9,80,64);
	trigger waittill( "trigger" );
 
 
	trigger = trigger;
	self playsound("betty_activated");
	wait(.1);	
	fake_model = spawn("script_model",self.origin);
	fake_model setmodel(self.model);
	self hide();
	tag_origin = spawn("script_model",self.origin);
	tag_origin setmodel("tag_origin");
	tag_origin linkto(fake_model);
	playfxontag(level._effect["betty_trail"], tag_origin,"tag_origin");
	fake_model moveto (fake_model.origin + (0,0,32),.2);
	fake_model waittill("movedone");
	playfx(level._effect["betty_explode"], fake_model.origin);
	earthquake(1, .4, fake_model.origin, 512);

	//CHris_P - betties do no damage to the players
	zombs = getaispeciesarray("axis");
	for(i=0;i<zombs.size;i++)
	{
		//PI ESM: added a z check so that it doesn't kill zombies up or down one floor
		if(zombs[i].origin[2] < fake_model.origin[2] + 80 && zombs[i].origin[2] > fake_model.origin[2] - 80 && DistanceSquared(zombs[i].origin, fake_model.origin) < 200 * 200)
		{
			zombs[i] thread maps\_zombiemode_spawner::zombie_damage( "MOD_ZOMBIE_BETTY", "none", zombs[i].origin, self.owner );
		}
	}
	//radiusdamage(self.origin,128,1000,75,self.owner);

	trigger delete();
	fake_model delete();
	tag_origin delete();
	if( isdefined( self ) )
	{
		self delete();
	}
}

How do I get betty.owner in the thread?

Marked as best answer by jbird 11 years ago

Reply #5 on: June 21, 2015, 09:25:12 am

daedra descent
Community Daedra
2,789 Posts
230 Respect +1

Quote from: jbird on June 21, 2015, 09:20:52 am

How do I get betty.owner in the thread?

Code Snippet

Plaintext

trigger thread player_trigger(self.owner);

Code Snippet

Plaintext

player_trigger(owner)

Code Snippet

Plaintext

if (players[i] isTouching (self) && players[i] != owner)

Reply #6 on: June 21, 2015, 09:25:25 am

Harry Bo21
Scripter
6,875 Posts
908 Respect +1

thread it on the betty?

add that value to the trigger?

you really need to look up the basics, not hating, but adding a argument to a function is scripting lesson number 1....

Reply #7 on: June 21, 2015, 09:31:14 am

Quote from: Harry Bo21 on June 21, 2015, 09:25:25 am

thread it on the betty?

add that value to the trigger?

you really need to look up the basics, not hating, but adding a argument to a function is scripting lesson number 1....

Never had to do that before, now I know for future reference

Reply #8 on: June 21, 2015, 09:33:28 am

Harry Bo21
Scripter
6,875 Posts
908 Respect +1

youve never had to use a argument in a function?...

seriously. im not hating, you NEED to go look up the basics if you wanna get better...

	Benevolent Soul who has our eternal gratitude and exclusive access to betas and the donator section of the forum.
	Has shown effort and knowledge in the area of scripting while being a part of the UGX-Mods community.

UGX-Mods Login

Betty Trigger Help