First in _zombiemode look for this:

round_spawning()
{
	level endon( "intermission" );
/#
	level endon( "kill_round" );
#/

And change it into this:

round_spawning()
{
	level endon( "intermission" );
	level endon( "stop_round_spawning" );
/#
	level endon( "kill_round" );
#/

---

Then use this script for the trigger:

kill_round_trigger()
{
	cost = 1500;
	user = undefined;
 
	trig = getent( "end_round_trigger", "targetname" );
	trig setCursorHint("HINT_NOICON");
	trig UseTriggerRequireLookAt();
	trig SetHintString( "Press &&1 to end the round. Cost: "+cost );
 
	while(1)
	{
		trig waittill( "trigger", user );
 
		if( user.score < cost )
			continue;
 
		trig disable_trigger();
		user maps\_zombiemode_score::minus_to_player_score( cost );
 
		level notify( "stop_round_spawning" );
		zombies = GetAiSpeciesArray( "axis", "all" );
		for( i=0 ; i<zombies.size ; i++ )
		{
			zombies[i] dodamage( zombies[i].health+666, zombies[i].origin );
			wait 0.05;
		}
 
		// Cooldown time
		wait 60;
		trig enable_trigger();
	}
}

Could i use this with a trigger multiple and without cost and without the hintstring and only 1 time usable because i want to use this to teleport in a bossroom.

kill_round_trigger()
{
	trig = getent( "end_round_trigger", "targetname" );
 
	trig waittill( "trigger" );
	level notify( "stop_round_spawning" );
	zombies = GetAiSpeciesArray( "axis", "all" );
	for( i=0 ; i<zombies.size ; i++ )
	{
		zombies[i] dodamage( zombies[i].health+666, zombies[i].origin );
		wait 0.05;
	}
 
	trig delete();
}

kill_round_trigger()
{
	trig = getent( "end_round_trigger", "targetname" );
 
	trig waittill( "trigger" );
	level notify( "stop_round_spawning" );
	zombies = GetAiSpeciesArray( "axis", "all" );
	for( i=0 ; i<zombies.size ; i++ )
	{
		zombies[i] dodamage( zombies[i].health+666, zombies[i].origin );
		wait 0.05;
	}
 
	trig delete();
}