#include common_scripts\utility;
#include maps\_utility;
#include maps\_zombiemode_utility;
#include maps\_loadout;

init()
{
	PreCacheShader("shader");
	level thread onPlayerConnect();
}

onPlayerConnect()
{
	for( ;; )
	{
		level waittill( "connecting", player );

		player thread onPlayerSpawned();
	}
}

onPlayerSpawned()
{
	self endon( "disconnect" );

	for( ;; )
	{
		self waittill( "spawned_player" );
		self thread OverlayStart();
	}
}

OverlayStart()
{
	self endon("death");
	self endon("disconnect");

	self.overlay = create_simple_hud( self );
	self.overlay.sort = 1;
	self.overlay.hidewheninmenu = true;
	self.overlay.alignX = "left";
	self.overlay.alignY = "top";
	self.overlay.horzAlign = "fullscreen";
	self.overlay.vertAlign = "fullscreen";
	self.overlay SetShader( "shader", 640, 480 );
	self.overlay.alpha = 0;
	self thread destroyOverlayDeath();
	self thread toggleableOverlay();
}

toggleableOverlay()
{
	self endon("death");
	self endon("disconnect");

	overlayEnabled = false;

	while( true )
	{
		if( self UseButtonPressed() && self AdsButtonPressed() )
		{
			if(overlayEnabled)
			{
				overlayEnabled = false;
				self.overlay FadeOverTime(0.2);
				self.overlay.alpha = 0;
				wait 0.45;
			}
			else
			{
				overlayEnabled = true;
				self.overlay FadeOverTime(0.2);
				self.overlay.alpha = 1;
				wait 0.45;
			}
		}
		wait 0.05;
	}
}

destroyOverlayDeath()
{
	self waittill("death");

	self.overlay Destroy();
}